topic Re: time interval block in Application Development and Automation Discussions

time interval block

former_member512327 — Mon, 14 Sep 2020 13:50:19 GMT

Hi,

Given a timestamp value, how can we derive it into 30 mins interval so I can assign them into “30 mins block”?

Example 1, timestamp value 20200630000149 so this is actually Date: 30.06.2020, Time: 00:01:49. This will be first 30 mins interval, so the “30 mins block” is 1.

Example 1, timestamp value 20200630003850 so this is actually Date: 30.06.2020, Time: 00:38:50. This will be secon 30 mins interval, so the “30 mins block” is 2.

Any FM can do this?

Thanks in advance.

Re: time interval block

FredericGirod — Mon, 14 Sep 2020 13:58:47 GMT

result = cond #( when char_timestamp+10(2) lt '30' then '1' else '2' ).

something like that ?

Re: time interval block

MateuszAdamus — Mon, 14 Sep 2020 14:04:26 GMT

Hello fujibau

Get the separate date and time values first with the CONVERT TIME STAMP keyword: https://help.sap.com/doc/abapdocu_751_index_htm/7.51/en-us/abapconvert_time-stamp.htm

Then, from time variable.

DATA:
  lv_hours TYPE i,
  lv_minutes TYPE i,
  lv_segment TYPE i.

lv_hours = lv_time+0(2).
lv_minutes = lv_time+2(2).

lv_hours = lv_hours + 1.

lv_segment = lv_hours * 2.
IF lv_minutes < 30.
  lv_segment = lv_segment - 1.
ENDIF.

Kind regards,
Mateusz

Re: time interval block

Sandra_Rossi — Mon, 14 Sep 2020 14:55:02 GMT

Why a function module if ABAP is much shorter?

Remember that if you convert a type T variable into I (integer), SAP converts the time into seconds.

DATA(block) = CONV t( char_timestamp+8(6) ) DIV 1800 + 1. " 1800 seconds = 30 minutes

Examples:

DATA: char_timestamp TYPE c LENGTH 14,
      block          TYPE i.

char_timestamp = '2020063000149'.
block = CONV t( char_timestamp+8(6) ) DIV 1800 + 1.
ASSERT block = 1.

char_timestamp = '20200630003850'.
block = CONV t( char_timestamp+8(6) ) DIV 1800 + 1.
ASSERT block = 2.

EDIT: be carefult concerning the Time Zone in which the time is expressed, 11am in France (9 or 10am UTC) is not the same 11am in South Korea (~2am UTC). UTC is the same time for anyone in the Universe/World, now is 9:39am for everyone in the world. If you want a "UTC block number" you have to convert your time to UTC, and you first have to know in what time zone is expressed your time. For more information, see Michael P. answer and comment.

Re: time interval block

former_member512327 — Mon, 14 Sep 2020 22:57:50 GMT

Hi All,

Many thanks for your input.

It is not only following 2 timestamp, it can be anytime timestamp during a day (24 hours).

timestamp value 20200630000149

timestamp value 20200630003850

Example:

timestamp value 20200630103850

timestamp value 20200630203050

timestamp value 20200630111850

Any help is much apprecaited.

Re: time interval block

michael_piesche — Tue, 15 Sep 2020 06:26:08 GMT

The following coding converts any time between 00:00:00 and 23:59:59 into 30-minute blocks, starting with block 1:

" When using the '/' operator for decimal division on a time variable, 
" the commercial rounding at half values has to be taken into account 
DATA(block) = ( time + CONV t( '001500' ) ) / 1800.

" When using the 'DIV' operator for an integer division on a time variable
" the division result will only be based on the integer part and the remainder will be neglected
" this is what Sandra already posted
DATA(block) = time DIV 1800 + 1

Block 1 is from 00:00:00 to 00:29:59
Block 2 is from 00:30:00 to 00:59:59
...
Block 48 is from 23:30:00 t 23:59:59

The following report displays different inputs as blocks and block intervals of 30-minutes:

REPORT ztest_time_blocks.

TYPES: BEGIN OF ty_input_s,
         timestamp TYPE timestamp,
         timezone  TYPE timezone,
         date      TYPE dats,
         time      TYPE tims,
       END OF ty_input_s,
       ty_input_t TYPE TABLE OF ty_input_s WITH EMPTY KEY,
       BEGIN OF ty_output_s.
         INCLUDE TYPE ty_input_s.
         TYPES: block      TYPE i,
         block_from TYPE tims,
         block_to   TYPE tims,
       END OF ty_output_s,
       ty_output_t TYPE TABLE OF ty_output_s WITH EMPTY KEY.

" Example Input Data
DATA(input) = VALUE ty_input_t( ( timestamp = '20200630000149' timezone = 'UTC' )
                                ( timestamp = '20200630003850' timezone = 'UTC'  )
                                ( timestamp = '20200630103850' timezone = 'UTC'  )
                                ( timestamp = '20200630203050' timezone = 'UTC'  )
                                ( timestamp = '20200630231850' timezone = 'UTC'  ) ).

" Converting Timestamp based on Timezone to Date/Time and vice versa
LOOP AT input ASSIGNING FIELD-SYMBOL(<in>) WHERE timezone IS NOT INITIAL.
  IF <in>-timestamp IS NOT INITIAL AND <in>-time IS INITIAL.
    CONVERT TIME STAMP <in>-timestamp TIME ZONE <in>-timezone INTO DATE <in>-date TIME <in>-time.
  ELSEIF <in>-date IS NOT INITIAL AND <in>-time IS NOT INITIAL AND <in>-timestamp IS INITIAL.
    CONVERT DATE <in>-date TIME <in>-time INTO TIME STAMP <in>-timestamp TIME ZONE <in>-timezone.
  ENDIF.
ENDLOOP.

" creating block info for output
DATA(output) = VALUE ty_output_t( FOR wa IN input 
               ( timestamp = wa-timestamp
                  timezone = wa-timezone
                      date = wa-date
                      time =     wa-time
                     block =     wa-time DIV 1800 + 1
                block_from =   ( wa-time DIV 1800 ) * 1800
                  block_to = ( ( wa-time DIV 1800 ) + 1 ) * 1800 - 1 ) ).
*                    block =   ( wa-time + CONV t( '001500' ) ) / 1800
*               block_from = ( ( wa-time + CONV t( '001500' ) ) / 1800 - 1 ) * 1800
*                 block_to = ( ( wa-time + CONV t( '001500' ) ) / 1800 - 1 ) * 1800 + CONV t( '002959' ) ) ).

" Display output
cl_demo_output=>display( output ).

Timestamp vs Date/Time:

Timestamps should in general be based on UTC. Only when displaying timestamp values as date/time values the applicable timezone has to be applied in order to correctly display the date time values.

In your case, you are wanting to create blocks based on 30-minute time intervals for a time value with a specific timezone.

The following input example illustrates this relationship:

"  EST    M0500    USA     X          Eastern Time (New York)
"  UTC    P0000    NONE    X          UTC+0
"  CET    P0100    EUROPE  X          Central Europe
"  JAPAN  P0900    NONE    X          Japan

DATA(input) = VALUE ty_input_t( ( timestamp = '20200630000149' timezone = 'EST'   )
                                ( timestamp = '20200630000149' timezone = 'UTC'   )
                                ( timestamp = '20200630000149' timezone = 'CET'   )
                                ( timestamp = '20200630000149' timezone = 'JAPAN' )
                                ( timestamp = '20200630003850' timezone = 'EST'   )
                                ( timestamp = '20200630003850' timezone = 'UTC'   )
                                ( timestamp = '20200630003850' timezone = 'CET'   )
                                ( timestamp = '20200630003850' timezone = 'JAPAN' ) ).

Creating 30 minute blocks

The creation of 30 minute blocks is achieved by dividing the time into 30 minute intervals = 1'800 seconds (instead of 60 minute = 3'600 seconds intervals for the whole hours)
In order to correclty assign a time into a bloc, implicit or explicit rounding has to be taken into account:
a) So if explict rounding would be used, decimal values would always be rounded down to zero in order to assign the right block
b) If, like in this case, implicit rounding with integers is being applied, there will be a commercial rounding based on half values, so in order to compensate this implicit rounding, we have to adjust the value by the half of a block which is 15 minutes
block_of_time == ( time +/- 15minutes ) / 1800seconds
Also in this case, the blocks should start with 1 instead of 0, so we either need to add the 15 minutes before rounding, or when subtracting the 15 minutes, there needs to be the value 1 added to the calculated block

Here is an input example for 60 values in 3 minute steps starting at 23:59:59:

DATA(input) = VALUE ty_input_t( for j = 0 then j + 1 while j < 60
                              ( timestamp = conv timestamp( sy-datum && conv t( j * 180 - 1 ) ) timezone = 'UTC' ) ).

Displaying the block's time intervals

In order to display the time interval for a block, the block value is multiplied by 1'800 seconds for the start of the interval and for the end of the interval the value 29 minutes and 59 seconds is added.

The following input example displays all 48 blocks and the corresponding intervals:

DATA(input) = VALUE ty_input_t( for j = 0 then j + 1 while j < 48
                              ( timestamp = conv timestamp( sy-datum && conv t( j * 1800 ) ) timezone = 'UTC' ) ).

Re: time interval block

MateuszAdamus — Tue, 15 Sep 2020 06:47:05 GMT

This is what Sandra's logic provides. Just use it with different timestamps and you will get different block numbers.

Kind regards,
Mateusz

Re: time interval block

Sandra_Rossi — Tue, 15 Sep 2020 07:01:06 GMT

Please use button COMMENT if you don't propose a solution. The button ANSWER is reserved to proposing a solution.

Re: time interval block

michael_piesche — Tue, 15 Sep 2020 08:52:27 GMT

sandra.rossi, I totally agree with the calculation part of your solution which creates the half-hour blocks based on a time field. And based on the specifics of the OP's question, you are providing the basic coding how the conversion of the timestamp into a time field could be done.

However, this conversion will only be useful, if the timestamp and the relevant date/time is based on UTC, or even worse, if the timestamp is not based on UTC but on the same time zone as the relevant date/time.
If the blocks should be based on e.g. the System or the User Time Zone, the provided conversion logic will fail, if the timestamp is correctly based on UTC.

In general, timestamps should always be handled in UTC.

Thats why the statement "GET TIME STAMP FIELD time_stamp." returns a timestamp in UTC
And thats also why the statements "CONVERT TIME STAMP ..." as well as "CONVERT ... INTO TIME STAMP" require a Time Zone

Only when displaying timestamp values as date/time values, the applicable timezone has to be applied in order to correctly display the date time values.

I believe the OP needs to be made aware of the possible shortsightedness of the presented requirements.

Re: time interval block

Sandra_Rossi — Tue, 15 Sep 2020 09:52:22 GMT

michael.piesche Well, you have the right approach in explaining all these things to people, but it takes a lot of time (bravo to you), and people often just don't want to spend more time on their initial question.

What I did is to edit my answer and refer to your question.

Note that the problem is much more complex, because maybe the OP situation is to calculate a "local" block number. For example the block number used to know how many parcels are delivered in the world in the morning rather than in the afternoon (morning and afternoon have a "local" meaning). A "UTC block number" (or whatever time zone is chosen as a reference) has an interest only if you want something like know the number of people using an internet website by block of 30 minutes.

Re: time interval block

former_member512327 — Tue, 15 Sep 2020 13:20:09 GMT

Thanks michael.piesche.

In that case, if I want to create 15 mins block instead of 30 mins, can I divide by 900 instead of 1800

example:

block =     wa-time DIV 900 + 1

Re: time interval block

michael_piesche — Tue, 15 Sep 2020 13:29:08 GMT

yes 😉

" 24 hours have 24*60*60 seconds
"  - if you divide 24 hours by 3'600 seconds, you get 24 blocks with 60 minute time intervals (hours)
"  - if you divide 24 hours by 1'800 seconds, you get 48 blocks with 30 minute time intervals (half-hours)
"  - if you divide 24 hours by   900 seconds, you get 96 blocks with 15 minute time intervals (quarter-hours)

Re: time interval block

phil_moh — Mon, 05 Oct 2020 00:48:14 GMT

Hi,

Can you explain again why must we have "+ 1" in the following formula:

block= wa-time DIV 900 + 1

Thanks