topic Re: SAP Community Coding Challenge - March 2020 in Application Development and Automation Discussions

SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 13:47:43 GMT

This is the voting thread for the March 2020 SAP Community Coding Challenge. For the challenge details and directions see this blog:

https://blogs.sap.com/2020/02/28/sap-community-coding-challenge-series/

In this Question thread I will post the 7 finalist. Use the answer voting mechanism to choose the one solution you believe should be the overall winner. Remember: this is all for fun and education. We are all winners here because of the great knowledge sharing!

Re: SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 13:49:09 GMT

Finalist #1: CL_ABAP_MATCHER Approach

By pawelgrzeskowiak

    SPLIT condense( sentence ) AT space INTO TABLE DATA(words).


    out->write( |Number of words: { lines( words )  } | ).


    LOOP AT words ASSIGNING FIELD-SYMBOL(<word>).
      DATA(matcher) = NEW cl_abap_matcher(
                      regex = NEW cl_abap_regex( pattern = '(.)(?!.*\1)' )
                      text  =  <word> ).
      out->write( |Number of unique characters in the word: { <word> } - {  lines( matcher->find_all( ) )  } | ).
    ENDLOOP.

Re: SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 13:51:48 GMT

Finalist #2: Regex Approach

By: alexander_frank

    SPLIT condense( sentence ) AT space INTO TABLE DATA(words).
    out->write( |Number of words: { lines( words ) }| ).
    LOOP AT words REFERENCE INTO DATA(word).
      DATA(unique_chars_in_word) = replace( val = word->* regex = `(.)(?=.*\1)` with = `` occ = 0 ).
      out->write( |Number of unique characters in the word: { word->* } - { strlen( unique_chars_in_word ) }| ).
    ENDLOOP.

Re: SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 13:52:52 GMT

Finalist #3: For/Group By Approach

By: sougata.chatterjee

    SPLIT condense( sentence ) AT space INTO TABLE DATA(lt_words).
    out->write( |Number of Words: { lines( lt_words ) }| ).

    LOOP AT lt_words ASSIGNING FIELD-SYMBOL(<word>).
      out->write(
    |Number of unique characters in the word: { <word> } - {
       lines( VALUE string_table(
        FOR GROUPS x OF y
        IN VALUE string_table(
            FOR i = 0 THEN i + 1
            UNTIL i = strlen( <word> ) ( <word>+i(1) ) )
            GROUP BY y ( x ) ) ) }| ).
    ENDLOOP.

Re: SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 13:53:58 GMT

Finalist #4: SELECT DISTINCT Approach

By: dominik.bigl2

    SPLIT condense( sentence ) AT | | INTO TABLE DATA(words).
    out->write( |Number of words: { lines( words ) } | ).

    LOOP AT words ASSIGNING FIELD-SYMBOL(<word>).
      DATA(characters) = VALUE ABAP_SORTORDER_tab( FOR char = 0 THEN char + 1 UNTIL char = strlen( <word> ) ( name = <word>+char(1) ) ).
      SELECT DISTINCT * FROM @characters AS characters INTO TABLE @DATA(unique_characters).
      out->write( |Number of unique characters in the word: { <word> } - { lines( unique_characters ) } | ).
    ENDLOOP.

Re: SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 13:56:09 GMT

Finalist #5: Single Line Solution

By: christian.guenter

 out->write( CONV string(
                          LET sentence = `ABАP  is excellent `
                              match_word_regex = `\w+`
                              match_duplicate_chars_regex = `(.)(?=.*\1)`
                              num_of_words = count( val   = sentence
                                                    regex = match_word_regex )
                          IN REDUCE #( INIT output = |Number of words: { num_of_words }|
                                       FOR word_index = 1 WHILE word_index <= num_of_words
                                       LET word = match( val   = sentence
                                                         regex = match_word_regex
                                                         occ   = word_index )
                                           num_of_unique_chars = numofchar( replace( val   = word
                                                                                     regex = match_duplicate_chars_regex
                                                                                     occ   = 0
                                                                                     with  = space ) )
                                       IN NEXT output = output && |\nNumber of unique characters in word: { word } - { num_of_unique_chars }| ) ) ).

Re: SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 13:57:26 GMT

Finalist #6: Sorted Table Discarding Duplicates Approach

By: jacques.nomssi

    TYPES sorted_char_table TYPE SORTED TABLE OF string WITH UNIQUE DEFAULT KEY.
    DO.
      TRY.
          DATA(word) = segment( val = sentence index = sy-index space = ` ` ).
          DATA(characters) = VALUE string_table( FOR idx = 0 UNTIL idx = numofchar( word )  ( word+idx(1)  ) ).
          DATA(chars_in_word) = CORRESPONDING sorted_char_table( characters DISCARDING DUPLICATES ).
         out->write( |Number of unique characters in the word:{ word } - { lines( chars_in_word ) }| ).

        CATCH cx_sy_strg_par_val.
          out->write( |Number of words:{  sy-index - 1 }| ).
          EXIT.
      ENDTRY.
    ENDDO.

Re: SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 13:58:31 GMT

Finalist #7: Reduce Approach

By: dinumbabu

    SPLIT sentence AT ` ` INTO TABLE DATA(words).
    DELETE words WHERE table_line IS INITIAL.
    out->write( |no of words: { lines( words ) } | ).

    LOOP AT words ASSIGNING FIELD-SYMBOL(<word>).
      out->write( |Number of unique characters in the word: { <word> } - {
                                  REDUCE i( INIT len = 1
                                            FOR n = 1  WHILE ( n <= strlen( <word> ) - 1 )
                                            NEXT len =  len + COND #( WHEN <word>+0(n) CA <word>+n(1) THEN 0 ELSE 1  ) ) } | ).
    ENDLOOP.

Re: SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 14:03:37 GMT

We also have the replay of the live stream where we announced the finalist available: https://youtu.be/4riDYGR_t_o

Re: SAP Community Coding Challenge - March 2020

Peter_Inotai — Tue, 17 Mar 2020 14:04:55 GMT

I was really looking forward to see the final solutions. I really love the "SELECT DISTINCT" and the "Sorted Table Discarding Duplicates" Approach.

Congratulation for all the finalist and special award winners.

Re: SAP Community Coding Challenge - March 2020

Former Member — Tue, 17 Mar 2020 14:12:56 GMT

absolutly love it !

Re: SAP Community Coding Challenge - March 2020

rothkl — Tue, 17 Mar 2020 14:33:40 GMT

perfect solution!

Re: SAP Community Coding Challenge - March 2020

Sandra_Rossi — Tue, 17 Mar 2020 14:42:52 GMT

FROM @ works only with HANA

Re: SAP Community Coding Challenge - March 2020

Sandra_Rossi — Tue, 17 Mar 2020 14:45:35 GMT

Who will check that nobody does a vote +1 for their favorite and -1 for others? 😉

Re: SAP Community Coding Challenge - March 2020

former_member744839 — Tue, 17 Mar 2020 14:47:56 GMT

love this solution!

Re: SAP Community Coding Challenge - March 2020

Former Member — Tue, 17 Mar 2020 14:52:18 GMT

perfect solution

Re: SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 14:52:21 GMT

sandra.rossi - https://help.sap.com/doc/abapdocu_752_index_htm/7.52/en-US/abapselect_itab.htm

Re: SAP Community Coding Challenge - March 2020

EnnoWulff — Tue, 17 Mar 2020 14:52:37 GMT

How many solutions did you get overall?

Re: SAP Community Coding Challenge - March 2020

thomas_jung — Tue, 17 Mar 2020 14:55:29 GMT

enno.wulff - a little shy of 200 entries.

Re: SAP Community Coding Challenge - March 2020

Sandra_Rossi — Tue, 17 Mar 2020 14:56:39 GMT

I mean, in Open SQL, SELECT ... FROM @ is only supported if the database is HANA (*). For instance, SAP Sybase ASE (16.0) doesn't support it (Developer Edition 7.52). Of course, it works with the ABAP Cloud environment, but generally speaking, many SAP clients don't have HANA (yet).

(*) EDIT:

SELECT DISTINCT works only if the database is HANA.

Complete explanation: FROM @ITAB works from 7.52 only if

either the SQL statement is really simple (no join, no order by, no distinct, etc.) so it's executed by ABAP kernel,
or it's not really simple and it's executed by the database and only HANA currently supports it.