topic Re: Dynamic CREATE OBJECT with parameters REF TO interface. in Application Development and Automation Discussions

Dynamic CREATE OBJECT with parameters REF TO interface.

matt — Fri, 27 Dec 2019 19:41:36 GMT

I'm trying to dynamically call the constructor of a class, where the parameters are with reference to an interface. However, I keep getting the dump DYN_CALL_METH_PARAM_TYPE, CX_SY_DYN_CALL_ILLEGAL_TYPE.

An attempt was made to pass a current parameter to formal parameter "IO_MESSAGING" of method "CONSTRUCTOR" of class "/UI2/CL_FLP_CONT_MGR". This resulted in a type conflict.

I've tried using RTTS, CREATE DATA dat TYPE REF TO (classname), and I get the same error. Anyone have any ideas how to get this working. Sample code which demonstrates the issue is below. This is running on a 754, s4hana system.

DATA lt_tile_tm_combination TYPE /ui2/if_flp_cont_mgr=>tt_tile_tm_combination_sorted.
DATA lo_flp_cont_mgr TYPE REF TO object. " /ui2/if_flp_cont_mgr.
DATA lo_catalog_api TYPE REF TO object.  " /ui2/if_fdm_catalog_api.
DATA lo_messaging TYPE REF TO object.    " /ui2/if_fcm_messaging.
DATA lx_root TYPE REF TO cx_root.
TRY.
    CREATE OBJECT lo_catalog_api TYPE ('/UI2/CL_FDM_CATALOG_API')
      EXPORTING
        iv_scope     = 'CUST' "or 'CONF'
        iv_use_cache = abap_true.
  CATCH cx_root INTO lx_root.
    MESSAGE lx_root TYPE 'E'.
ENDTRY.
CREATE OBJECT lo_messaging TYPE ('/UI2/CL_FCM_MESSAGING').
CREATE OBJECT lo_flp_cont_mgr TYPE ('/UI2/CL_FLP_CONT_MGR') "/ui2/cl_flp_cont_mgr
  EXPORTING
    iv_scope = 'CUST'
    io_catalog_api = lo_catalog_api " TYPE REF TO /UI2/IF_FDM_CATALOG_API
    io_messaging = lo_messaging.    " TYPE REF TO /UI2/IF_FCM_MESSAGING
CALL METHOD lo_flp_cont_mgr->('/UI2/IF_FLP_CONTR_MGR~GET_ALL_TILES_TMS')
    RECEIVING rt_tile_tm_combination = lt_tile_tm_combination.

Re: Dynamic CREATE OBJECT with parameters REF TO interface.

Former Member — Fri, 27 Dec 2019 21:50:22 GMT

The problem is that you are using generic reference variables with type object to access the instances you created and passing them to the constructor leads to type conflicts as the variable's static type is examined during runtime. Is there a specific reasons why you are avoiding interface types? This way it should be working:

DATA lt_tile_tm_combination TYPE /ui2/if_flp_cont_mgr=>tt_tile_tm_combination_sorted.
DATA lo_flp_cont_mgr TYPE REF TO /ui2/if_flp_cont_mgr.
DATA lo_catalog_api TYPE REF TO /ui2/if_fdm_catalog_api.
DATA lo_messaging TYPE REF TO /ui2/if_fcm_messaging.
DATA lx_root TYPE REF TO cx_root.

TRY.
    CREATE OBJECT lo_catalog_api TYPE ('/UI2/CL_FDM_CATALOG_API')
      EXPORTING
        iv_scope     = 'CUST' "or 'CONF'
        iv_use_cache = abap_true.
  CATCH cx_root INTO lx_root.
    MESSAGE lx_root TYPE 'E'.
ENDTRY.
CREATE OBJECT lo_messaging TYPE ('/UI2/CL_FCM_MESSAGING').
CREATE OBJECT lo_flp_cont_mgr TYPE ('/UI2/CL_FLP_CONT_MGR')
  EXPORTING
    iv_scope = 'CUST'
    io_catalog_api = lo_catalog_api
    io_messaging = lo_messaging.

lt_tile_tm_combination = lo_flp_cont_mgr->get_all_tiles_tms( ).

Other option would be to apply the CAST operator, if for some reason the variable types cannot be altered:

CREATE OBJECT lo_flp_cont_mgr TYPE ('/UI2/CL_FLP_CONT_MGR')
  EXPORTING
    iv_scope       = 'CUST'
    io_catalog_api = CAST /ui2/if_fdm_catalog_api( lo_catalog_api )
    io_messaging   = CAST /ui2/if_fcm_messaging( lo_messaging ).

lt_tile_tm_combination = CAST /ui2/if_flp_cont_mgr( lo_flp_cont_mgr )->get_all_tiles_tms( ).

Re: Dynamic CREATE OBJECT with parameters REF TO interface.

matt — Sat, 28 Dec 2019 06:26:04 GMT

Sorry, I missed out a vital piece of information. The code must be syntactically correct in a 7.31 system that doesn't contain these classes and interfaces, and actually run on the 7.54 system!. The types used in the data definitions don't exist in 7.31, but they're easy to replicate.

Re: Dynamic CREATE OBJECT with parameters REF TO interface.

matt — Sat, 28 Dec 2019 06:53:59 GMT

Re: Dynamic CREATE OBJECT with parameters REF TO interface.

Former Member — Sat, 28 Dec 2019 08:26:44 GMT

matthew.billingham

So the codebase is common, but actually will run only on a higher release? The serious limitation here is even though everything can be done dynamically at source level type checks against references take place during execution. And there is no way to bypass that.

What about generating and calling a subroutine where the result is taken over from if the classes exist?

Or, if additional program objects are permitted on 7.54 outsource the release dependent logic to a class which is dynamically referenced from the common code.

TRY.

  CALL METHOD ('ZCL_MY_HIGHER_RELEASE_STUFFS')=>('GET_RESULTS')
    RECEIVING results = results.

CATCH cx_sy_dyn_call_illegal_class.
  " Lower system version
ENDTRY.

Re: Dynamic CREATE OBJECT with parameters REF TO interface.

Sandra_Rossi — Sat, 28 Dec 2019 08:47:47 GMT

I don't understand if there is still a question here.

This 7.40+ downcast statement:

DATA more_general TYPE REF TO object.
DATA(less_general) = CAST less_general_object_type( more_general ).

is equivalent to this code in releases before 7.40:

DATA more_general TYPE REF TO object.
DATA less_general TYPE REF TO less_general_object_type.
less_general ?= more_general.

Re: Dynamic CREATE OBJECT with parameters REF TO interface.

Former Member — Sat, 28 Dec 2019 09:02:21 GMT

sandra.rossi

As far as I understand the though part is that the source to be written cannot contain static reference to the interfaces, because it must compile also on lower release where those do not exist

Re: Dynamic CREATE OBJECT with parameters REF TO interface.

matt — Mon, 30 Dec 2019 07:19:12 GMT

sandra.rossi It's because the less_general_object_type doesn't exist in 7.31

The types are correct at runtime, so it's peculiar that it doesn't work on 7.4+.

Re: Dynamic CREATE OBJECT with parameters REF TO interface.

Sandra_Rossi — Mon, 30 Dec 2019 08:24:31 GMT

Thanks, gabmarian, matthew.billingham, I understand now. I don't see an ABAP solution because it's an ABAP limitation: the short dump you get at runtime is equivalent to the syntax error if you use the static call of the method:

DATA lo_flp_cont_mgr TYPE REF TO /ui2/cl_flp_cont_mgr.
DATA lo_catalog_api TYPE REF TO object.
DATA lo_messaging TYPE REF TO object.
CREATE OBJECT lo_flp_cont_mgr
EXPORTING
iv_scope       = 'CUST'
io_catalog_api = lo_catalog_api "syntax error "LO_CATALOG_API" is not type-compatible with formal parameter "IO..."
io_messaging   = lo_messaging.  "syntax error "LO_MESSAGING" is not type-compatible with formal parameter "IO..."

Either you don't copy the code to the 7.31 system (several source systems) or you generate the source code at runtime (GENERATE SUBROUTINE POOL).

Re: Dynamic CREATE OBJECT with parameters REF TO interface.

matt — Mon, 30 Dec 2019 11:41:17 GMT

It's as sandra.rossi said - it can't be done using dynamic ABAP. The solution I've adopted is to generate the code of the method once at runtime. I've not included the method interface_exists. This can be implemented easily using the RTTS.

The first time the constructor of the class runs, the method get_all_tiles_tms has its comment lines removed, but only if the interface /UI2/IF_FLP_CONT_MGR exists.

CLASS zcl_dynamic_method_change_demo DEFINITION
  PUBLIC
  FINAL
  CREATE PUBLIC .

  PUBLIC SECTION.
    TYPES: tt_tile_tm_combination_sorted TYPE string_table. 
    " I'm using string_Table here. but for it work in our 754 system
    " we need to create our own Z version of the real type
    " /ui2/if_flp_cont_mgr=>tt_tile_tm_combination_sorted
    METHODS constructor .
    METHODS get_all_tiles_tms
      RETURNING
        value(r_result) TYPE tt_tile_tm_combination_sorted .
  PROTECTED SECTION.
  PRIVATE SECTION.
    METHODS method_not_initialised
      RETURNING
        value(r_result) TYPE abap_bool.
    METHODS initialise_method.
    METHODS strip_out_comments
      IMPORTING
        i_source_code   TYPE siw_tab_code
      RETURNING
        value(r_result) TYPE siw_tab_code.
ENDCLASS.

CLASS zcl_dynamic_method_change_demo IMPLEMENTATION.
  METHOD constructor.
    IF interface_exists( '/UI2/IF_FLP_CONT_MGR' ) EQ abap_false.
      MESSAGE 'Cannot be run on this system' TYPE 'E'.
    ENDIF.
    IF method_not_initialised( ) EQ abap_false.
      initialise_method( ).
      MESSAGE 'Please restart transaction. You should not see this message again'
         TYPE 'E'.
    ENDIF.
  ENDMETHOD.

  METHOD get_all_tiles_tms.
*    DATA lt_tile_tm_combination TYPE /ui2/if_flp_cont_mgr=>tt_tile_tm_combination_sorted.
*    DATA lo_flp_cont_mgr TYPE REF TO /ui2/if_flp_cont_mgr.
*    DATA lo_catalog_api TYPE REF TO /ui2/if_fdm_catalog_api.
*    DATA lo_messaging TYPE REF TO /ui2/if_fcm_messaging.
*    DATA lx_root TYPE REF TO cx_root.
*    TRY.
*        CREATE OBJECT lo_catalog_api TYPE /ui2/cl_fdm_catalog_api
*          EXPORTING
*            iv_scope     = 'CUST' "or 'CONF'
*            iv_use_cache = abap_true.
*      CATCH cx_root INTO lx_root.
*        MESSAGE lx_root TYPE 'E'.
*    ENDTRY.
*    CREATE OBJECT lo_messaging TYPE /ui2/cl_fcm_messaging.
*    CREATE OBJECT lo_flp_cont_mgr TYPE /ui2/cl_flp_cont_mgr
*      EXPORTING
*        iv_scope       = 'CUST' "or 'CONF'
*        io_catalog_api = lo_catalog_api
*        io_messaging   = lo_messaging.
*    r_result = lo_flp_cont_mgr->get_all_tiles_tms( ).
  ENDMETHOD.

  METHOD initialise_method.
    DATA writer TYPE REF TO if_siw_repository_writer.
    writer = cl_siw_resource_access=>s_get_instance( ).
    DATA source_code TYPE siw_tab_code.
    TRY.
        writer->read_method_source(
                  EXPORTING
                    i_clsname    = 'ZCL_DYNAMIC_METHOD_CHANGE_DEMO'
                    i_methodname = 'GET_ALL_TILES_TMS'
                    i_state      = 'I'
                   IMPORTING
                     e_tab_code = source_code ).
        source_code = strip_out_comments( source_code ).
        writer->write_class_method(
            i_clsname     = 'ZCL_DYNAMIC_METHOD_CHANGE_DEMO'
            i_methodname  = 'GET_ALL_TILES_TMS'
            i_tab_code    = source_code ).
        DATA rf_error TYPE REF TO cx_siw_resource_failure..
      CATCH cx_siw_resource_failure.
        MESSAGE rf_error TYPE 'E'.
    ENDTRY.
  ENDMETHOD.

  METHOD method_not_initialised.
    DATA writer TYPE REF TO if_siw_repository_writer.
    writer = cl_siw_resource_access=>s_get_instance( ).
    DATA source_code TYPE siw_tab_code.
    TRY.
        writer->read_method_source(
                  EXPORTING
                    i_clsname    = 'ZCL_DYNAMIC_METHOD_CHANGE_DEMO'
                    i_methodname = 'GET_ALL_TILES_TMS'
                    i_state      = 'I'
                   IMPORTING
                     e_tab_code = source_code ).
        DATA rf_error TYPE REF TO cx_siw_resource_failure.
      CATCH cx_siw_resource_failure INTO rf_error.
        MESSAGE rf_error TYPE 'E'.
    ENDTRY.
    r_result = abap_false.
    FIELD-SYMBOLS <source_code_line> TYPE siw_dte_code.
    LOOP AT source_code ASSIGNING <source_code_line>.
      CHECK sy-tabix NE 1 AND sy-tabix NE lines( source_code )
                          AND ( <source_code_line> IS INITIAL 
                            OR <source_code_line>(1) NE '*' ).
      r_result = abap_true.
      EXIT.
    ENDLOOP.
  ENDMETHOD.

  METHOD strip_out_comments.
    r_result = i_source_code.
    FIELD-SYMBOLS <source_code_line> TYPE siw_dte_code.
    LOOP AT r_result ASSIGNING <source_code_line>.
      CHECK sy-tabix NE 1 AND sy-tabix NE lines( r_result ) 
                          AND <source_code_line> IS NOT INITIAL
                          AND <source_code_line>(1) EQ '*'.
      <source_code_line> = <source_code_line>+1.
    ENDLOOP.
  ENDMETHOD.
ENDCLASS.