tabstrip on selection screen

Former Member — Mon, 28 Jul 2014 11:00:31 GMT

Hi All,

I have created selection screen with 3 tab strips.

i have 2 radios button in each tab strip. My problem is, when i have selected first radio button from 2nd tab strip and execute, then it is executing first tab strip radio button first and when i click on back button then my second tab strip radio button getting executed.

So could you please do let me know, how to execute directly 2nd tab strip radio button directly wiht out executing first tab strip.

Regards,

Re: tabstrip on selection screen

Former Member — Mon, 28 Jul 2014 11:24:16 GMT

Hello,

Assign a user command to each tab strip as follows.

************************************************************************

SELECTION-SCREEN BEGIN OF BLOCK sel .

************************************************************************

SELECTION-SCREEN SKIP.

*---------------------------* TABSTRIP *-------------------------------*

SELECTION-SCREEN BEGIN OF TABBED BLOCK tabb1 FOR 15 LINES.

SELECTION-SCREEN TAB (40) title1 USER-COMMAND ucomm1 DEFAULT SCREEN 1001.

SELECTION-SCREEN TAB (40) title2 USER-COMMAND ucomm2 DEFAULT SCREEN 1002.

SELECTION-SCREEN TAB (40) title3 USER-COMMAND ucomm3 DEFAULT SCREEN 1003.

SELECTION-SCREEN END OF BLOCK tabb1.

*-------------------------* --------- *-------------------------------*

SELECTION-SCREEN END OF BLOCK sel.

*-------------------------* SCREEN 1001 *------------------------------*

SELECTION-SCREEN: BEGIN OF SCREEN 1001 AS SUBSCREEN .

SELECTION-SCREEN: BEGIN OF BLOCK b1 WITH FRAME TITLE title.

PARAMETERS: radio_button1 RADIOBUTTON GROUP rad DEFAULT 'X'.

"Insert all your other radio button in the first tabstrip here

SELECTION-SCREEN: END OF BLOCK b1 .

SELECTION-SCREEN: END OF SCREEN 1001 .

*-------------------------* --------- *-------------------------------*

*-------------------------* SCREEN 1002 *------------------------------*

SELECTION-SCREEN: BEGIN OF SCREEN 1002 AS SUBSCREEN .

SELECTION-SCREEN: BEGIN OF BLOCK b2 WITH FRAME TITLE titlex.

PARAMETERS: radio_button2 RADIOBUTTON GROUP rad1.

"Insert all your other radio button in the second tabstrip here

SELECTION-SCREEN: END OF BLOCK b2 .

SELECTION-SCREEN: END OF SCREEN 1002 .

*-------------------------* --------- *-------------------------------*

*-------------------------* SCREEN 1003 *------------------------------*

SELECTION-SCREEN: BEGIN OF SCREEN 1003 AS SUBSCREEN .

SELECTION-SCREEN: BEGIN OF BLOCK b3 WITH FRAME TITLE titlexx.

PARAMETERS: radio_button3 RADIOBUTTON GROUP rad2.

"Insert all your other radio button in the third tabstrip here

SELECTION-SCREEN: END OF BLOCK b3 .

SELECTION-SCREEN: END OF SCREEN 1003 .

*-------------------------* --------- *-------------------------------*

In this case the first tabstrip has the user command UCOMM1, the second tabstrip has the user command UCOMM2 and likewise for the third and last tabstrip.

Now in the START-OF-SELECTION event.

Start by doing a case for active tabs before doing a check which radio button is selected as follows.

CASE tabb1-activetab.

WHEN 'UCOMM1'. "First tabstrip

CASE 'X'. "To check which radio button is checked

"Here you do the processing upon the radio button selected.

WHEN radio_button1.

CALL TRANSACTION 'SE38'.

ENDCASE.

WHEN 'UCOMM2'. "Second tabstrip

CASE 'X'. "To check which radio button is checked

"Here you do the processing upon the radio button selected.

WHEN radio_button2.

CALL TRANSACTION 'SE11'.

ENDCASE.

WHEN 'UCOMM3'. "Third tabstrip

CASE 'X'. "To check which radio button is checked

"Here you do the processing upon the radio button selected.

WHEN radio_button3.

CALL TRANSACTION 'SE09'.

ENDCASE.

Hope it helps.

Thanks and Kind Regards,

Yovish.

Message was edited by: Yovish Bissessur

Re: tabstrip on selection screen

Former Member — Mon, 28 Jul 2014 11:55:50 GMT

Thank you very much Yovish. It is working fine.

Re: tabstrip on selection screen

Former Member — Mon, 28 Jul 2014 12:12:13 GMT

Good

topic Re: tabstrip on selection screen in Application Development and Automation Discussions

tabstrip on selection screen

Re: tabstrip on selection screen

Re: tabstrip on selection screen

Re: tabstrip on selection screen