Find variable name in runtime

adrianos_campanhola — Mon, 30 Jun 2014 18:01:47 GMT

Hello,

I'll explain this question in 2 parts , the general idea and it's intents

I've been trying to do some dynamic coding and I still didn't manage a way to find out a variable name at runtime.

I wanted to pass the variable into a method/subroutine and find out what is the variable name along with some other properties:

o_dynsel->add_select_option( s_matnr[] ).

Here's the idea:

While using the dynamic selection FM's (FREE_SELECTION_INIT), I wanted to map the select-options I have on screen to their corresponding fields inside the function. This can be achieved If:

I know the name of the select option variable and its table-field. -> So I can map it and ensure unicity.
I know it's contents -> to map from/to the dynamic selection screen/

Plus, I wanted to do this as generic as possible.

I could do this using a text with the variable name:

o_dynsel->add_select_option( i_selop = 'S_MATNR'

i_ref_field = 'MARA-MATNR' ).

But I simply don't like it that way(plus, I can always get spelling errors! )

Re: Find variable name in runtime

Former Member — Tue, 01 Jul 2014 10:02:47 GMT

You will only have access to actual parameter, not that format parameter.

If the variable name is not being passed, you can read the call stack , read the code where it was called, and then do string manipulation to get the variable name.

Look at this snippet where method is able to return the names select-options being passed.

*----------------------------------------------------------------------* 
CLASS main DEFINITION. 
  PUBLIC SECTION. 
    METHODS: 
    find_name 
      IMPORTING selopt TYPE ANY TABLE 
      RETURNING value(result) TYPE string. 
 
ENDCLASS.                    "main DEFINITION 
*----------------------------------------------------------------------* 
CLASS main IMPLEMENTATION. 
  METHOD find_name. 
 
    TYPES: 
      BEGIN OF formatted_entry, 
              stack_depth TYPE tpda_stack_level, 
              kind TYPE tpda_event_type, 
              progname TYPE tpda_program, 
              includename TYPE tpda_include, 
              line TYPE tpda_sc_line, 
              event TYPE tpda_event, 
           END OF formatted_entry, 
      formatted_entry_stack TYPE STANDARD TABLE OF formatted_entry WITH DEFAULT KEY . 
 
    DATA lt_stack TYPE formatted_entry_stack. 
    lt_stack =  cl_abap_get_call_stack=>format_call_stack_with_struct( 
                  cl_abap_get_call_stack=>get_call_stack( ) 
                ). 
 
    DATA ls_stack TYPE formatted_entry. 
    DATA lt_report TYPE TABLE OF string. 
    DATA lv_report TYPE string. 
    READ TABLE lt_stack INTO ls_stack INDEX 2. 
    IF sy-subrc EQ 0. 
      READ REPORT ls_stack-includename INTO lt_report. 
      IF sy-subrc EQ 0. 
        READ TABLE lt_report INTO lv_report INDEX ls_stack-line. 
        IF sy-subrc EQ 0. 
          TRANSLATE lv_report TO UPPER CASE. 
          FIND REGEX '->FIND_NAME\W*(\w*)\W*' IN lv_report SUBMATCHES result. 
        ENDIF. 
      ENDIF. 
    ENDIF. 
  ENDMETHOD.                    "find_name 
ENDCLASS.                    "main IMPLEMENTATION 
 
TABLES mara. 
SELECT-OPTIONS: 
  s_matnr FOR mara-matnr, 
  s_mtart FOR mara-mtart. 
 
START-OF-SELECTION. 
  DATA lv_name TYPE string. 
  DATA lr_main TYPE REF TO main. 
  CREATE OBJECT lr_main. 
 
  lv_name = lr_main->find_name( s_matnr[] ). 
  WRITE / lv_name. 
  lv_name = lr_main->find_name( s_mtart[] ). 
  WRITE / lv_name. 
 

topic Find variable name in runtime in Application Development and Automation Discussions

Find variable name in runtime

Re: Find variable name in runtime