topic Re: Expand internal table at runtime in Application Development and Automation Discussions

Expand internal table at runtime

Former Member — Tue, 15 Apr 2014 09:30:44 GMT

Hello guys,

i have a problem with my internal table.

i create a dynamical internal table with:

CREATE DATA lt_object1 TYPE STANDARD TABLE OF ('VBAK').
ASSIGN lt_object1->* TO <gt_object>.

This works fine. but after this statement i have a fixed structure of the table VBAK. i have to add an another column to my internal table, because i need the field input_style TYPE lvc_t_styl, for my ALV-GRID.

I tried also to create the dynamical table with the CALL METHOD cl_alv_table_create=>create_dynamic_table, but then i get a issue with the widht of my internal table, compared to the real table.

does anyone have a solution for this?

best regards

Re: Expand internal table at runtime

Former Member — Tue, 15 Apr 2014 09:44:21 GMT

Hi,

for LVC_T_STYL is a table type and not a simple column I don't know, if this is possible for a dynamic internal table. Maybe this is not supported.

Regards,

Klaus

Re: Expand internal table at runtime

Former Member — Tue, 15 Apr 2014 09:48:34 GMT

hi,

thanks i used LVC_T_STYL in a another programm. but there i had to handle this only for one fixed table not for more tables.

so i dont know how to expand my internal table.

Re: Expand internal table at runtime

Former Member — Tue, 15 Apr 2014 09:50:28 GMT

Hi,

maybe class CL_ABAP_TABLEDESCR may solve your issue, but I have no experience with it.

Regards,

Klaus

Re: Expand internal table at runtime

former_member192842 — Tue, 15 Apr 2014 11:09:05 GMT

Hi,

Please go through the below link, you may get an idea.

http://zevolving.com/2008/09/dynamic-internal-table-creation/

Dynamic Internal Table with Deep structure | ABAP Help Blog

Regards

Anand

Re: Expand internal table at runtime

SuhaSaha — Tue, 15 Apr 2014 11:53:24 GMT

Hello,

First-of-all a very unique name

Anyway the RTTS classes are very intuitive and you can think of creating the components of a runtime structure similar to creating a static structure.

The algorithm is as follows -

Get the components(read: fields) from the data reference you have created earlier.
Add the component, type LVC_T_STYL, to the table from (1).
Get the RTTC instance of the table using the component table from (2).
Create the data reference using the RTTC handle from (3).

So you can try this code snippet

DATA dref_tab TYPE REF TO data.
CREATE DATA dref_tab TYPE STANDARD TABLE OF ('SFLIGHT').
ASSIGN dref_tab->* TO FIELD-SYMBOL(<tab>).
* Get the fields from the data reference
DATA(comp_tab) =
CAST cl_abap_structdescr(
     CAST cl_abap_tabledescr(
          cl_abap_typedescr=>describe_by_data_ref( dref_tab )
          )->get_table_line_type( )
     )->get_components( ).
* Add the field for the "Style" element
DATA component TYPE abap_componentdescr.
component-name = `STYLE`.
component-type
= CAST cl_abap_tabledescr(
       cl_abap_typedescr=>describe_by_name( 'LVC_T_STYL' )
       ).
APPEND component TO comp_tab.
TRY .
    DATA(oref_rttc_tab) =
    cl_abap_tabledescr=>get( cl_abap_structdescr=>get( comp_tab ) ).
  CATCH ##no_handler
        cx_sy_struct_creation
        cx_sy_table_creation.
ENDTRY.
DATA dref_tab_alv TYPE REF TO data.
CREATE DATA dref_tab_alv TYPE HANDLE oref_rttc_tab.
UNASSIGN <tab>.
ASSIGN dref_tab_alv->* TO <tab>.

BR,

Suhas

PS - Please excuse me i can't stop loving ABAP 740

Re: Expand internal table at runtime

bassanders40 — Wed, 22 Mar 2023 15:55:17 GMT

We have to have a small discussion about intuitive, but.... For me it worked out perfectly