topic Re: Popup BAPI return messages in Application Development and Automation Discussions

Popup BAPI return messages

Former Member — Mon, 24 Feb 2014 21:43:16 GMT

Hello experts,

I would like a way to quickly handle the BAPI return table (TYPE TABLE OF bapiret2). I would like to pass the table into a function module or helper method to popup all the messages at once. This is the same way MIGO (and many other programs) do a popup of messages with little red, yellow, and green icons to the left. Currently I am using a series of calls to function module BAL_LOG_... and I feel there has to be a better way.

I tried searching for the answer to this question, but if the answer exists, it is buried within the noise of a million people saying use 'POPUP_TO_CONFIRM' and other function modules. To clarify: I do not want buttons to confirm. I want a popup of a list of messages with red, yellow, and green icons on the left.

Whoever answers my question correctly will henceforth be referred to by me as "the Magnificent."

Re: Popup BAPI return messages

Former Member — Mon, 24 Feb 2014 22:34:10 GMT

Hi Eric,

you can call in sequence FMs MESSAGES_INITIALIZE, MESSAGE_STORE (for every message to show in the popup windows) and MESSAGES_SHOW.

You can easily set up a little test, but if you need you can search in SCN: there's a lot of examples.

Marco

Re: Popup BAPI return messages

former_member223133 — Tue, 25 Feb 2014 06:01:32 GMT

Hi Eric,

You can use the function module " MRM_PROT_FILL" to populate the messages into message tab.

Below is the source code:

*   Set error message
         ls_err-msgty = c_msgty.
         ls_err-msgid = c_msgid.
         ls_err-msgno = c_msgno.
         ls_err-msgv1 = ls_drseg-ebelp.
         ls_err-source = c_source.
         ls_err-rblgp = ls_drseg-rblgp.
         ls_err-shown = c_shown.
         APPEND ls_err TO lt_err.
*   Populate the message into message tab
         CALL FUNCTION 'MRM_PROT_FILL'
           TABLES
             t_errprot = lt_err.

Append all your messages to lt_err . It works well.

Thanks

Gangadhar

Re: Popup BAPI return messages

Former Member — Tue, 25 Feb 2014 18:50:26 GMT

Re: Popup BAPI return messages

Former Member — Tue, 25 Feb 2014 18:53:03 GMT

I'm not sure how those constants work, and when I tried this nothing happened. More explanation might be helpful.

Re: Popup BAPI return messages

vamsixk — Wed, 26 Feb 2014 04:35:11 GMT

Hi Eric,

you can use the FM FINB_BAPIRET2_DISPLAY.

It accepts as internal table of type BAPIRET2 and pops it to the screen.

Cheers!

Regards,

Vamsi

Re: Popup BAPI return messages

Former Member — Wed, 26 Feb 2014 17:27:24 GMT

That is even simpler than Gangadhar's answer, but it doesn't allow me to set the SEND_IF_ONE parameter.

Re: Popup BAPI return messages

SuhaSaha — Wed, 26 Feb 2014 22:38:06 GMT

My 2 cents ...

IF_RECA_MESSAGE_LIST is the most convenient message handler i have used so far So i would use it in this way -

Get the instance using the factory class CF_RECA_MESSAGE_LIST=>CREATE( ).
Add the BAPI messages using the method ADD_FROM_BAPI( ).
Get the handle via GET_HANDLE( ) & display using function BAL_DSP_LOG_DISPLAY.

DATA(o_msg_list) = cf_reca_message_list=>create( ). 
 
o_msg_list->add_from_bapi( 
  EXPORTING 
    it_bapiret = VALUE #( id = 'BC_IBF' 
                        ( type = 'I'  number = '008' ) 
                          type = 'E' ( number = '050' message_v1 = 'AA') 
                                     ( number = '051' message_v1 = 'BB') 
                                     ( number = '055' message_v1 = 'CC') 
                        ) ) . 
 
DATA st_log_disp_prof TYPE bal_s_prof. 
 
CALL FUNCTION 'BAL_DSP_PROFILE_POPUP_GET' 
  IMPORTING 
    e_s_display_profile = st_log_disp_prof. 
 
st_log_disp_prof-use_grid   = abap_true. 
st_log_disp_prof-disvariant 
  = VALUE #( handle = o_msg_list->get_handle( ) 
             report = sy-repid 
           ). 
 
CALL FUNCTION 'BAL_DSP_LOG_DISPLAY' 
  EXPORTING 
    i_s_display_profile  = st_log_disp_prof 
  EXCEPTIONS 
    profile_inconsistent = 1 
    internal_error       = 2 
    no_data_available    = 3 
    no_authority         = 4 
    OTHERS               = 5. 
IF sy-subrc <> 0. 
* Implement suitable error handling here 
ENDIF. 

BR,

Suhas

Re: Popup BAPI return messages

itzssreddy — Mon, 13 Jul 2015 11:45:32 GMT

Hi Eric,

Can you tell me how did you manage to store multiple messages and show them in a single display pop up.

Thanks,

Sree