topic Re: Function Module WS_DELIVERY_UPDATE_2 not updateing Picking/putaway confirmation in Application Development and Automation Discussions

Function Module WS_DELIVERY_UPDATE_2 not updateing Picking/putaway confirmation

Former Member — Thu, 21 Feb 2013 08:18:01 GMT

Hi Experts,

I'm using FM 'WS_DELIVERY_UPDATE_2' to process picking on a modbile scanner.

Everything is working well except the "Picking/Putaway confirmation (LEDLVSTATDISPITEM-KOQUA)' Status is not getting updated and remains on 'B'.

My Code:

wa_vbkok-vbeln_vl = zsdmob_in01m-vbeln. "outbound delivery no
wa_vbkok-vbtyp_vl = 'J'.
wa_vbkok-kodat = sy-datum.
wa_vbkok-kouhr = sy-uzeit.
wa_vbkok-kzpod = 'V'.

* update picking for line item
CALL FUNCTION 'WS_DELIVERY_UPDATE_2'
    EXPORTING
      vbkok_wa                           = wa_vbkok
      COMMIT                             = 'X'
      delivery                           = zsdmob_in01m-vbeln
      update_picking                     = 'X'
      SYNCHRON                           = 'X'
   IMPORTING
     ef_error_any                       = wa_error
     ef_error_in_item_deletion          = w_error_in_item_deletion
     ef_error_in_pod_update             = w_error_in_pod_update
     ef_error_in_interface              = w_error_in_interface
     ef_error_in_goods_issue            = w_error_in_goods_issue
     ef_error_in_final_check            = w_error_in_final_check
     ef_error_partner_update            = w_error_partner_update
     ef_error_sernr_update              = w_error_sernr_update
   TABLES
     vbpok_tab                          = t_vbpok.

When I want to do Processes Goods Issue I get the Error "Picking request not yet confirmed".

Please avdise on any help to get this sorted.

Regards

Ian

Re: Function Module WS_DELIVERY_UPDATE_2 not updateing Picking/putaway confirmation

Former Member — Thu, 21 Feb 2013 10:15:11 GMT

Hi Ian,

Can you check manually is it working ? .

if not then check this Note 43124 - VL01, VL02 Picking Confirmation Status .

Regard's

Smruti

Re: Function Module WS_DELIVERY_UPDATE_2 not updateing Picking/putaway confirmation

Former Member — Thu, 21 Feb 2013 10:18:15 GMT

Hi Smrunti,

Manual is working fine. I will have a look at the note that you suggested.

Many thanks for your response

Regards

Re: Function Module WS_DELIVERY_UPDATE_2 not updateing Picking/putaway confirmation

Former Member — Mon, 25 Feb 2013 10:06:36 GMT

Hi guys,

Mannaged to get

'SD_DELIVERY_UPDATE_PICKING_1'

Working!

You must set vbpok-TAQUI = 'X' .

Also vbpok-vbeln & vbkok-vbeln must be equal to the Picking Request Doc no that is generated when you print the picking list and not the delivery number. Lost a couple of hours on this one!

Re: Function Module WS_DELIVERY_UPDATE_2 not updateing Picking/putaway confirmation

Former Member — Thu, 27 Mar 2014 19:51:57 GMT

Hello Ian,

I did exactly as you mentioned in your last post about the FM 'SD_DELIVERY_UPDATE_PICKING_1' still no errors, no updates. Will it be possible for you to copy paste the part where you populate parameters vbkok_wa & vbpok_tab of the FM.

Thanks a mil...

Regards,

Amit

Re: Function Module WS_DELIVERY_UPDATE_2 not updateing Picking/putaway confirmation

Former Member — Fri, 28 Mar 2014 06:35:12 GMT

Hi Amit,

See my code:

* Get outbount delivery details from Sales order no.

SELECT SINGLE * FROM vbfa

    WHERE vbelv   = zsdmob_in01m-vbeln    "ref doc = sales doc no

      AND vbtyp_n = 'Q'                   "doc type = pick request

      AND matnr   = zsdmob_in02m-matnr.   "matnr    = material number

wa_vbkok-vbeln_vl     = zsdmob_in01m-vbeln.      "outbound delivery no

wa_vbkok-vbeln        = vbfa-vbeln.

wa_vbkok-vbtyp_vl     = 'J'.

wa_vbkok-kodat        = sy-datum.

wa_vbkok-kouhr        = sy-uzeit.

wa_vbkok-kzpod        = 'B'.

wa_vbkok-wabuc        = 'X'.

IF v_answer = 'Y'.

    wa_vbkok-komue        = 'X'.

ENDIF.

SELECT * FROM lips

    WHERE vbeln = zsdmob_in01m-vbeln

    AND   matnr = zsdmob_in02m-matnr.

    MOVE-CORRESPONDING lips TO t_vbpok.

    t_vbpok-vbeln_vl = zsdmob_in01m-vbeln.

    t_vbpok-posnr_vl = lips-posnr.

    t_vbpok-orpos    = lips-posnr.

    t_vbpok-posnn    = lips-posnr.

    t_vbpok-vbeln    = vbfa-vbeln.

    t_vbpok-vbtyp_n = 'Q'.

    lt_prot-vbeln    = zsdmob_in01m-vbeln.

    lt_prot-posnr    = lips-posnr.

    lt_prot-matnr    = zsdmob_in02m-matnr.

    t_vbpok-taqui    = 'X'.

    lt_prot          = lips-vrkme.

    wa_vbkok-packing_refresh = 'X'.

    v_lips_lfimg     = lips-lfimg.

    v_meins          = lips-meins.

    v_vrkme          = lips-vrkme.

    t_vbpok-pikmg    = zsdmob_in02m-pikmg * lips-umvkz.

    t_vbpok-lfimg    = zsdmob_in02m-pikmg.

    t_vbpok-lgmng    = zsdmob_in02m-pikmg * lips-umvkz.

    lt_prot-lfimg    = zsdmob_in02m-pikmg.

    APPEND t_vbpok.

    APPEND lt_prot.

ENDSELECT.

IF zsdmob_in02m-pikmg < v_lips_lfimg

    AND v_answer = 'N'.

    CALL FUNCTION 'POPUP_TO_CONFIRM'

      EXPORTING

        titlebar              = 'Confirm'

        text_question         = 'Copy Pick Qty TO Delivery Qty'

        text_button_1         = 'Yes'

        text_button_2         = 'No'

        default_button        = '1'

        display_cancel_button = space

      IMPORTING

        answer                = ev_answer

      EXCEPTIONS

        text_not_found        = 1

        OTHERS                = 2.

    IF sy-subrc = 0.

      IF ev_answer = 1.

        wa_vbkok-komue        = 'X'.

      ELSE.

        wa_vbkok-komue        = ''.

      ENDIF.

    ENDIF.

    v_answer = 'N'.

ENDIF.

CALL FUNCTION 'SD_DELIVERY_UPDATE_PICKING_1'

    EXPORTING

      vbkok_wa     = wa_vbkok

      synchron     = ''

      aufrufer_t_1 = 'X'

    TABLES

      vbpok_tab    = t_vbpok

      prot         = lt_prot.

Re: Function Module WS_DELIVERY_UPDATE_2 not updateing Picking/putaway confirmation

Former Member — Fri, 28 Mar 2014 20:00:50 GMT

This doesn't work for delivery items which have a batch split or else it works like a charm.

Thanks for sharing the code!

Regards,

Amit