topic Replace leading Zero's in Application Development and Automation Discussions

Replace leading Zero's

Former Member — Wed, 10 Feb 2010 07:31:57 GMT

Hi ,

one of my field var = 0000501

I want to display it like var = ****501

I want to replace all leading zero's with ' * ' .

Replace statement replaces all zeros with ' * ' & display var = ***51.

I want my output = ****501.

Plz help

Thanks in Advance

Sai

Re: Replace leading Zero's

Former Member — Wed, 10 Feb 2010 07:40:33 GMT

Hello

Try this snippet:


data: str1(10),
      x type i,
      y type i.
str1 = '0000501'.
x = strlen( str1 ).
shift str1 left deleting leading '0'.
y = strlen( str1 ).
x = x - y.
do x times.
  concatenate '*' str1 into str1.
enddo.
write str1.

Re: Replace leading Zero's

Former Member — Wed, 10 Feb 2010 07:41:47 GMT

Hi,

Try this simple code:


DATA value(7) TYPE c VALUE '0000501'.

DATA i TYPE i.

WHILE value+i(1) EQ '0'.
  value+i(1) = '*'.
  ADD 1 TO i.
ENDWHILE.

WRITE value.

Re: Replace leading Zero's

Former Member — Wed, 10 Feb 2010 07:41:59 GMT

Hello,

Check this logic and modify if required according to your need.


data temp(7) type c.
data len type i.
data n type i.
temp = '0000501'.
len = strlen( temp ).
do len times.
  if temp+n(1) <> '0'.
    exit.
  else.
    replace '0' in temp+n(1) with '*' .
  endif.
  n = n + 1.
enddo.
write temp.

Hope this helps in solving your query.

Regards,

Sachin

Re: Replace leading Zero's

RichHeilman — Wed, 10 Feb 2010 07:44:57 GMT

How about something like this?

DATA: lv_init TYPE char07 VALUE '0000501'.
DATA: lv_conv TYPE char07.
DATA: lv_star TYPE char07 VALUE '*******'.
data: lv_outp type char07.
DATA: lv_init_l type i.
data: lv_conv_l type i.
data: lv_offset type i.

CALL FUNCTION 'CONVERSION_EXIT_ALPHA_OUTPUT'
  EXPORTING
    input  = lv_init
  IMPORTING
    output = lv_conv.

lv_init_l = strlen( lv_init ).
lv_conv_l = strlen( lv_conv ).
lv_offset = lv_init_l - lv_conv_l.
lv_outp = lv_star.
lv_outp+lv_offset(lv_conv_l) = lv_conv.

WRITE:/ lv_outp.

Regards,

RIch Heilman

Re: Replace leading Zero's

Former Member — Wed, 10 Feb 2010 07:54:48 GMT

thanks to all of u for there proper reply

Closing the thread

Sai

Re: Replace leading Zero's

Former Member — Wed, 10 Feb 2010 08:02:52 GMT

hi.

i tried coding below .

FIELD-SYMBOLS : <fs> type c .

do .

off = sy-index - 1.

assign text+off(1) to <fs> .

if <fs> <> 0.

exit .

else.

replace SECTION offset off length 1 of text with '*' .

endif.

enddo.