topic Re: Help with Update task in Application Development and Automation Discussions

Help with Update task

Former Member — Thu, 24 Sep 2009 14:14:42 GMT

Hi friends,

In the below am trying to update a custom table using a call function in update task. I dont see the table getting updated can someone take a look at it and let me knw what the problem is? I have the commit work statement and also marked the function module as an update one in the attribute. Please help me . Thanks in advance! kathy

*&---------------------------------------------------------------------*
*&  Include           ZINBOUND_TEST
*&---------------------------------------------------------------------*
Report: ZINBOUND_TEST.
DATA: l_dest     TYPE REF TO if_bgrfc_destination_inbound,
      l_unit     TYPE REF TO if_trfc_unit_inbound,
      l_inb_dest TYPE bgrfc_main_i_dst,
      lv_matid TYPE /sapapo/matid,
      lv_matnr TYPE /sapapo/matnr,
      lv_maktx type /SAPAPO/MAKTX,
      lv_langu  TYPE LANGU.

data: lt_product type  STANDARD TABLE OF ZUPDATE,
      ls_product type ZUPDATE.

lv_matid = '123'.
lv_langu = 'E'.
lv_maktx = 'Materia1'.


CALL FUNCTION 'Z_TEST' IN UPDATE TASK
  EXPORTING
    iv_matid = lv_matid
    iv_maktx = lv_maktx
    iv_langu = lv_langu .

COMMIT WORK.

select * from zupdate into corresponding fields OF TABLE lt_product.
if sy-subrc <> 0.
  write 'no records added'.
else.
  loop at lt_product into ls_product.

    write: / ls_product-MATID,
             ls_product-MAKTX.

  endloop.
endif.


FUNCTION Z_TEST.
*"----------------------------------------------------------------------
*"*"Update Function Module:
*"
*"*"Local Interface:
*"  IMPORTING
*"     VALUE(IV_MATID) TYPE  /SAPAPO/MATID
*"     VALUE(IV_MAKTX) TYPE  /SAPAPO/MAKTX
*"     VALUE(IV_LANGU) TYPE  LANGU
*"----------------------------------------------------------------------
data: itab type standard table of zupdate,

wa_itab type zupdate.

wa_itab-matid = iv_matid.
wa_itab-maktx = iv_maktx.
wa_itab-langu = iv_langu.

append wa_itab to itab.
update zupdate from table itab .

ENDFUNCTION.

Edited by: ka reddy on Sep 24, 2009 4:14 PM

Edited by: ka reddy on Sep 24, 2009 4:15 PM

Edited by: ka reddy on Sep 24, 2009 4:16 PM

Edited by: ka reddy on Sep 24, 2009 4:17 PM

Edited by: ka reddy on Sep 24, 2009 4:21 PM

Re: Help with Update task

naimesh_patel — Thu, 24 Sep 2009 14:27:28 GMT

I guess what you are trying to do in your code is Synchronous type of RFC. You call the FM to save the data in RFC and as soon as it finishes, you do the select to find out if database was updated.

bgRFC has more advanatages over the aRFC, qRFC, tRFC scenarios. Check this document: http://www.sdn.sap.com/irj/scn/index?rid=/library/uuid/b0401ea9-0be5-2910-b389-ce9675ab8af9

Regards,

Naimesh Patel

Re: Help with Update task

Former Member — Thu, 24 Sep 2009 14:28:35 GMT

HI,

Use COMMIT WORK AND WAIT.

Regards,

Ankur Parab

Re: Help with Update task

Former Member — Thu, 24 Sep 2009 14:31:00 GMT

Kathy - please check the help on UPDATE and MODIFY. In this case, I think you want to use MODIFY instead of UPDATE in your FM.

Rob

Re: Help with Update task

naimesh_patel — Thu, 24 Sep 2009 14:36:35 GMT

Actual question was about the Background RFC. While I was answering the question, questioner has changed it and made it for Update Task.

@Moderators: This should not be ALLOWED.

Regards,

Naimesh Patel

Re: Help with Update task

Former Member — Thu, 24 Sep 2009 14:42:02 GMT

Modify and update both didnt work. Is there something that am missing.

As far as i knw when it sees the commmit work it should excecute the FM but since the processing of the main prgm is not intrepreted the output should be 0 records and then the update to the table should have occured . Is it right?

Commit work and wait also doesnt work

Edited by: ka reddy on Sep 24, 2009 4:42 PM

Re: Help with Update task

Former Member — Thu, 24 Sep 2009 14:43:45 GMT

Hi Nalmesh I had doubts on both update and BGRFC but i thought i would get the update clarified first and then switch to BGRFC. Sorry for the inconvience.

Re: Help with Update task

Former Member — Thu, 24 Sep 2009 14:50:38 GMT


> Actual question was about the Background RFC. While I was answering the question, questioner has changed it and made it for Update Task.
> 
> @Moderators: This should not be ALLOWED.
> 
> Regards,
> Naimesh Patel

True - but hard to enforce short of locking or deleting. Kathy had asked an earlier question that I had locked because not enough research had been done. This shows more research so I didn't want to take action.

Rob

Re: Help with Update task

naimesh_patel — Thu, 24 Sep 2009 14:53:36 GMT

COMMIT WORK AND WAIT will stop the program exection until it finishes the High Priority Update Task type V1.

Check this help:

http://help.sap.com/saphelp_nw70/helpdata/EN/41/7af4dda79e11d1950f0000e82de14a/frameset.htm

To set your update FM as the high priority, you should use Update with immediate start or Update w. imm. start, no restart in the Update type specification of your FM.

http://help.sap.com/saphelp_nw70/helpdata/EN/41/7af4daa79e11d1950f0000e82de14a/frameset.htm


CALL FUNCTION 'Z_TEST' IN UPDATE TASK
  EXPORTING
    iv_matid = lv_matid
    iv_maktx = lv_maktx
    iv_langu = lv_langu .
 
COMMIT WORK AND WAIT.  "<<
 
select * from zupdate into corresponding fields OF TABLE lt_product.

Regards,

Naimesh Patel

Re: Help with Update task

Former Member — Thu, 24 Sep 2009 14:59:23 GMT

Thanks naimesh. It worked.

Now my second question is how can i use the advantage of BGRFC in the code above?

Re: Help with Update task

naimesh_patel — Thu, 24 Sep 2009 15:08:44 GMT

Update Task and RFC both are different techniques used for different purposes.

As you might have realized that, Update Task is used to start the Asynchronous update of the database in the SAME client. This way system will execute the database update as its convience and user of the Update Task doesn't have to wait. You can make this update call as the Synchronous by using the COMMIT WORK AND WAIT.

Whereas the RFC is used to perform certain activities, it might be Data Selection, Data Updation, Data manipulation on the same system or on the other System. There were 5 different types of RFC's till Netweaver 7 EP1. https://www.sdn.sap.com/irj/sdn/abap?rid=/library/uuid/f078394a-4469-2910-c4bf-853c75674694.

To overcome certain difficulties while doing aRFC, tRFC or qRFC (no sRFC) SAP has introduced the bgRFC from Netweaver 7 EP1. You can find the link of bgRFC in my first response.

I would recommonde reading both documents before diving into bgRFC.

You can also find certaiin examples of bgRFC here in docupedia:

https://cw.sdn.sap.com/cw/docs/DOC-38369

Regards,

Naimesh Patel

Re: Help with Update task

Former Member — Thu, 24 Sep 2009 15:11:57 GMT

I see that one advantage of using BGRFC over update task is that we can create multiple independent LUW without closing the earlier one using commit work. Not quite sure how to implement this? Kindly help me.

Re: Help with Update task

Former Member — Thu, 24 Sep 2009 15:15:53 GMT

Hey Naimesh thanks for the reply. yeah i read that document way before and i started taking a stab at implementing it.

I started with update task to see how it behaves and then wanted to go with BGRFC tats when i had the update issue.

Now that am done with update i want to implement BGRFC.

I have modified the earlier prgm...Can you give me some ideas how to extend this? Thanks!


*&---------------------------------------------------------------------*
*&  Include           ZBGRFC_INBOUND_TEST
*&---------------------------------------------------------------------*
Report: ZBGRFC_INBOUND_TEST.
DATA: l_dest     TYPE REF TO if_bgrfc_destination_inbound,
      l_unit     TYPE REF TO if_trfc_unit_inbound,
      l_inb_dest TYPE bgrfc_main_i_dst,
      lv_matid TYPE /sapapo/matid,
      lv_matnr TYPE /sapapo/matnr,
      lv_maktx type /SAPAPO/MAKTX,
      lv_matid1 TYPE /sapapo/matid,
      lv_matnr1 TYPE /sapapo/matnr,
      lv_maktx1 type /SAPAPO/MAKTX,
      lv_langu1  TYPE LANGU,
      lv_langu  TYPE LANGU.

data: lt_product type  STANDARD TABLE OF ZUPDATE,
      ls_product type ZUPDATE.

lv_matid = '125'.
lv_langu = 'E'.
lv_maktx = 'Materia3'.


**--Get the inbound destination for BGRFC.
  IF l_inb_dest IS INITIAL.
      SELECT SINGLE * FROM bgrfc_main_i_dst INTO l_inb_dest.
    ENDIF.
    l_dest = cl_bgrfc_destination_inbound=>create( l_inb_dest-destination ).
    l_unit = l_dest->create_trfc_unit( ).

CALL FUNCTION 'Z_TEST' IN BACKGROUND UNIT l_unit
  EXPORTING
    iv_matid = lv_matid
    iv_maktx = lv_maktx
    iv_langu = lv_langu .


select * from zupdate into corresponding fields OF TABLE lt_product.
if sy-subrc <> 0.
  write 'no records added'.
else.
  loop at lt_product into ls_product.

    write: / ls_product-MATID,
             ls_product-MAKTX.

  endloop.
endif.

Edited by: ka reddy on Sep 24, 2009 5:16 PM

Re: Help with Update task

naimesh_patel — Thu, 24 Sep 2009 15:32:15 GMT

Yes, we can try to achieve the functionality by using the bgRFC.

Use the method GET_UNIT_STATE to get the State of the Unit and wait until, the method retruns

IF_BGRFC_CLIENT=>UNIT_STATE_EXECUTED. Use caution, it might go in endless loop, if the Unit encouters some error while processing.

http://help.sap.com/saphelp_nw70/helpdata/en/0a/78534269a81218e10000000a155106/frameset.htm

Like:


CALL FUNCTION 'Z_TEST' IN BACKGROUND UNIT l_unit
  EXPORTING
    iv_matid = lv_matid
    iv_maktx = lv_maktx
    iv_langu = lv_langu .
 
COMMIT WORK.

" call method GET_UNIT_STATE and wait logic here...
 
select * from zupdate into corresponding fields OF TABLE lt_product.

Regards,

Naimesh Patel

Edited by: Naimesh Patel on Sep 24, 2009 10:46 AM - Added COMMIT WORK