topic Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries in Application Development and Automation Discussions

BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Thu, 03 Sep 2009 15:33:17 GMT

Hello,

I have been working on BAPI_ACC_DOCUMENT_POST bapi to create a WD application for creating an invoice similar to Tcode FB10. My issue is:-


The BAPI_ACC_DOCUMENT_POST" bapi is allowing the end user to make duplicate invoice payments which is not acceptable. We need the BAPI to return an error message if a duplicate entry exists. For eg:- If we enter a duplicate entry in FB10 it throws an error message telling the user that a duplicate entry exists. But, this is not happening in the case of the BAPI.

Could anyone help me in finding a way to check for duplicate invoice entries and throw an error message. I would greately appreciate your help.

Regards,

Gopal Yarlagadda.

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Thu, 03 Sep 2009 15:42:18 GMT

Is it not just a warning in FB10?

Rob

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Thu, 03 Sep 2009 15:44:29 GMT

In generally it means to check if there's an invoice with the same reference, so try to check the entries in BSIP table

Max

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Thu, 03 Sep 2009 15:47:50 GMT

Hello Rob,

No, in FB10 it is an error message "Check whether document has already been entered under number 1000 600000188 2009".

I think this has been configured in our system as a custom configuration.

Regards,

Gopal.

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Thu, 03 Sep 2009 15:57:21 GMT

That msg can be customized as warning or error.

Anyway the main fields of vendor invoice are stored in BSIP table, u can check this table in order to know if an invoice was just posted.

Max

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Thu, 03 Sep 2009 16:06:17 GMT

Hi Max,

Thanks for your reply. I checked in the table BSIP and I can see the duplicate entries being created. My problem is:-

Our system is not allowing duplicate entries through tcode:- FB10 or FB60. But, when when we enter an invoice through a Webdynpro Application created through BAPI_ACC_DOCUMENT_POST bapi, the BAPI is not returning any error message about the duplicate entries. Could you please help me about this problem. I would greatly appreciate your help.

Regard,

Gopal.

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Thu, 03 Sep 2009 16:22:01 GMT

just a thought: try out the same scenario by wrting a Z report prog. or in SE37, then check their results. Also check Cross company code flag, multiple currencies, posting keys

thanq

Edited by: SAP ABAPer on Sep 3, 2009 6:27 PM

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Thu, 03 Sep 2009 16:45:57 GMT

The BAPI doesn't call the fm FI_DUPLICATE_INVOICE_CHECK in order to check the posting: I was the same problem and I solved it by the BTE RWBAPI01, usually used to transfer the extension data.

If your release is ECC 6 u can also use the BADI acc_document (method change).

If you use the BTE u need to use a record dummy for extension in order to trigger the BTE

This is the code (Step 1):

.FUNCTION Z_SDFI_INTERFACE_RWBAPI01.
*"----------------------------------------------------------------------
*"*"Interfaccia locale:
*"  TABLES
*"      IT_ACCIT STRUCTURE  ACCIT
*"      IT_ACCCR STRUCTURE  ACCCR
*"      RETURN STRUCTURE  BAPIRET2
*"      EXTENSION STRUCTURE  BAPIACEXTC
*"      IT_ACCWT STRUCTURE  ACCIT_WT
*"  CHANGING
*"     VALUE(DOCUMENT_HEADER) LIKE  ACCHD STRUCTURE  ACCHD
*"----------------------------------------------------------------------
............................
  LOOP AT IT_ACCIT WHERE KOART = 'K'.

    IT_ACCIT-XUMSW = 'X'.
    MODIFY IT_ACCIT.

    SELECT SINGLE REPRF FROM LFB1 INTO _REPRF
                                           WHERE LIFNR = IT_ACCIT-LIFNR
                                             AND BUKRS = IT_ACCIT-BUKRS.
    IF SY-SUBRC <> 0.
      CLEAR _REPRF.
    ENDIF.

    READ TABLE IT_ACCCR WITH KEY POSNR = IT_ACCIT-POSNR.

Max

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Thu, 03 Sep 2009 16:46:12 GMT

The BAPI may not be returning it as an "Error" message but it may be there in the return table as a warning message. Please check the return table for all the messages.

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Thu, 03 Sep 2009 16:47:43 GMT

......Step 2

CALL FUNCTION 'FI_DUPLICATE_INVOICE_CHECK'
         EXPORTING
              I_BUKRS       = IT_ACCIT-BUKRS
              I_LIFNR       = IT_ACCIT-LIFNR
              I_WAERS       = IT_ACCCR-WAERS
              I_BLDAT       = IT_ACCIT-BLDAT
              I_XBLNR       = IT_ACCIT-XBLNR
              I_WRBTR       = IT_ACCCR-WRBTR
              I_KOART       = 'K'
              I_REPRF       = _REPRF
              I_SHKZG       = IT_ACCIT-SHKZG
              I_XUMSW       = IT_ACCIT-XUMSW
              I_BSTAT       = IT_ACCIT-BSTAT
              I_BLART       = IT_ACCIT-BLART
         EXCEPTIONS
              MISSING_DATA  = 1
              ERROR_MESSAGE = 2
              OTHERS        = 3.

    IF SY-SUBRC <> 0.
      CALL FUNCTION 'BALW_BAPIRETURN_GET2'
           EXPORTING
                TYPE   = SY-MSGTY
                CL     = SY-MSGID
                NUMBER = SY-MSGNO
                PAR1   = SY-MSGV1
                PAR2   = SY-MSGV2
                PAR3   = SY-MSGV3
                PAR4   = SY-MSGV4
           IMPORTING
                RETURN = RETURN.
      APPEND RETURN.
    ENDIF.

  ENDLOOP.

ENDFUNCTION.

Max

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Fri, 04 Sep 2009 08:05:45 GMT

Hi Max,

Thanks a lot for your reply. I appreciate your help. Actually, I am new to ABAP. So, could you please explain me of what to do in more detail. Can I insert the code into the my Webdynpro application so that my the duplicate entry check would be done??

I am sorry if I am causing any inconvenience. I appreciate your help and support.

Regards,

Gopal.

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Fri, 04 Sep 2009 08:07:45 GMT

Hi srinivas,

Thanks for your reply. I did check the return table and it doesn't show any warning messages as well!!! I haven't got a clue of what to do in this situation.

Regards,

Gopal.

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Fri, 04 Sep 2009 08:11:46 GMT

I suppose your Webdynpro just calls the BAPI, so u need any modification here, but only place the control inside the BAPI.

Let me know which tool u prefer to use:

BTE or BADI?

Max

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Fri, 04 Sep 2009 08:13:40 GMT

Hi Max,

I prefer the easiest way of doing this as I am a bit new to ABAP. I hope you can understand my situation!!

Regards,

Gopal.

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Fri, 04 Sep 2009 08:33:51 GMT

Start with following steps

- Run trx SE19

- Insert ACC_DOCUMENT in CLASSIC BADI section

- Press Create Impl.

- Insert Z_ACC_DOCUMENT as implementation name

- Press Enter

- Insert a short text in your implementation

- Add BKPFF as filter

- Active it

Max

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Fri, 04 Sep 2009 08:51:35 GMT

Hi Max,

I did what you said. What should I do next?

Regards,

Gopal.

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Fri, 04 Sep 2009 09:06:10 GMT

After activing the BADI the system should migrate it to the new BADI

Have you done it?

Max

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Fri, 04 Sep 2009 09:09:21 GMT

Hi Max,

Yes, I think I did the migration. Because I can see the field "Impl migrates to enhancement --Z_ACC_DOCUMENT" in the present screen. What should I do next?

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Fri, 04 Sep 2009 09:21:39 GMT

Now u need to implement the method CHANGE, so back to the BADI and press INTERFACE tab and double click on method CHANGE

Here u need to insert the code to check the duplicate posting

DATA: W_ACCIT  TYPE ACCIT.
  DATA: _REPRF   TYPE LFB1-REPRF.
  DATA: W_ACCCR  TYPE ACCCR.
  DATA: W_RETURN TYPE BAPIRET2.



  LOOP AT C_ACCIT INTO W_ACCIT WHERE KOART = 'K'.
* Check if the vendor has to be available for duplicete posting control
    SELECT SINGLE REPRF FROM LFB1 INTO _REPRF
       WHERE LIFNR = W_ACCIT-LIFNR
         AND BUKRS = W_ACCIT-BUKRS.
    IF SY-SUBRC <> 0.
      CLEAR _REPRF.
    ENDIF.

    READ TABLE C_ACCCR INTO W_ACCCR WITH KEY POSNR = W_ACCIT-POSNR.

    CALL FUNCTION 'FI_DUPLICATE_INVOICE_CHECK'
      EXPORTING
        I_BUKRS       = W_ACCIT-BUKRS
        I_LIFNR       = W_ACCIT-LIFNR
        I_WAERS       = W_ACCCR-WAERS
        I_BLDAT       = W_ACCIT-BLDAT
        I_XBLNR       = W_ACCIT-XBLNR
        I_WRBTR       = W_ACCCR-WRBTR
        I_KOART       = 'K'
        I_REPRF       = _REPRF
        I_SHKZG       = W_ACCIT-SHKZG
        I_XUMSW       = W_ACCIT-XUMSW
        I_BSTAT       = W_ACCIT-BSTAT
        I_BLART       = W_ACCIT-BLART
      EXCEPTIONS
        MISSING_DATA  = 1
        ERROR_MESSAGE = 2
        OTHERS        = 3.

    IF SY-SUBRC <> 0.
      CALL FUNCTION 'BALW_BAPIRETURN_GET2'
        EXPORTING
          TYPE   = SY-MSGTY
          CL     = SY-MSGID
          NUMBER = SY-MSGNO
          PAR1   = SY-MSGV1
          PAR2   = SY-MSGV2
          PAR3   = SY-MSGV3
          PAR4   = SY-MSGV4
        IMPORTING
          RETURN = W_RETURN.
      APPEND W_RETURN TO C_RETURN.
    ENDIF.

  ENDLOOP.

Max

Re: BAPI_ACC_DOCUMENT_POST posting duplicate entries

Former Member — Fri, 04 Sep 2009 09:25:40 GMT

Hi Max,

I did insert the code in the "Change" method and activated the method as well. What should I do next? Sorry for asking you every step. Your help is very much appreciated!

Regards,

Gopal.

Edited by: Gopal on Sep 4, 2009 11:25 AM