topic Re: about dynamic internal table in Application Development and Automation Discussions

about dynamic internal table

former_member410940 — Sun, 21 Jun 2009 12:36:12 GMT

Hi Experts,

Here i created a selection screen with two fields .

one field to hold the table name.

another for field name.

now i want to fetch this field values from the table entered by the user.

so, to hold this field values i have to create a internal table.

so, how to create it?

Thanks in advance.

Re: about dynamic internal table

Former Member — Sun, 21 Jun 2009 17:06:48 GMT

Hi,

To create a dynamic internal table make use of class CL_ALV_TABLE_CREATE and the method CREATE_DYNAMIC_TABLE.

You will have to pass a fieldcatalog to create the internal table.

Regards,

Ankur Parab

Re: about dynamic internal table

Former Member — Sun, 21 Jun 2009 17:13:20 GMT

Hi,

Have a look in the following code.



  type-pools : abap. 
  field-symbols: <dyn_table> type standard table, 
               <dyn_wa>, 
               <dyn_field>. 
  data: dy_table type ref to data, 
      dy_line  type ref to data, 
      xfc type lvc_s_fcat, 
      ifc type lvc_t_fcat. 
  selection-screen begin of block b1 with frame. 
parameters: p_table(30) type c default 'T001'. 
selection-screen end of block b1. 
  start-of-selection. 
    perform get_structure. 
  perform create_dynamic_itab.      **********Creates a dyanamic internal table********** 
  perform get_data. 
  perform write_out. 
  form get_structure. 
  data : idetails type abap_compdescr_tab, 
       xdetails type abap_compdescr. 
  data : ref_table_des type ref to cl_abap_structdescr. 
  * Get the structure of the table. 
  ref_table_des ?=  
      cl_abap_typedescr=>describe_by_name( p_table ). 
  idetails[] = ref_table_des->components[]. 
    loop at idetails into xdetails. 
    clear xfc. 
    xfc-fieldname = xdetails-name . 
    xfc-datatype = xdetails-type_kind. 
    xfc-inttype = xdetails-type_kind. 
    xfc-intlen = xdetails-length. 
    xfc-decimals = xdetails-decimals. 
    append xfc to ifc. 
  endloop. 
  endform. 
  form create_dynamic_itab. 
  * Create dynamic internal table and assign to FS 
  call method cl_alv_table_create=>create_dynamic_table 
               exporting 
                  it_fieldcatalog = ifc 
               importing 
                  ep_table        = dy_table. 
    assign dy_table->* to <dyn_table>. 
  * Create dynamic work area and assign to FS 
  create data dy_line like line of <dyn_table>. 
  assign dy_line->* to <dyn_wa>. 
  endform. 
    
  form get_data. 
  * Select Data from table. 
  select * into table <dyn_table> 
             from (p_table). 
  endform. 
   Write out data from table. 
  loop at <dyn_table> into <dyn_wa>. 
    do. 
      assign component  sy-index   
         of structure <dyn_wa> to <dyn_field>. 
      if sy-subrc <> 0. 
        exit. 
      endif. 
      if sy-index = 1. 
        write:/ <dyn_field>. 
      else. 
        write: <dyn_field>. 
      endif. 
    enddo. 
  endloop

Regards,

Abhinab Mishra

Re: about dynamic internal table

uwe_schieferstein — Sun, 21 Jun 2009 18:39:38 GMT

Hello

A less complicated solution looks like this:


DATA:
  gdo_data          TYPE REF TO data.

FIELD-SYMBOLS:
  <gt_itab>         TYPE TABLE.


PARAMETER:
  p_tabnam         TYPE tabname   DEFAULT 'KNB1'.

START-OF-SELECTION.

  CREATE DATA gdo_data TYPE TABLE OF (p_tabnam).
  ASSIGN gdo_data->* TO <gt_itab>.

  SELECT * FROM (p_tabnam) INTO TABLE <gt_itab> UP TO 10 ROWS.

END-OF-SELECTION.

Regards

Uwe

Re: about dynamic internal table

former_member410940 — Tue, 14 Jul 2009 10:07:56 GMT

thanks