topic Re: Search Help using 'F4IF_INT_TABLE_VALUE_REQUEST', in Application Development and Automation Discussions

Search Help using 'F4IF_INT_TABLE_VALUE_REQUEST',

Former Member — Mon, 09 Mar 2009 07:40:00 GMT

Do not post in ALL CAPITALS

I AM USING FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST' FOR MY SEARCH HELP

THE LIST OF VALUE APPERS I CHOOCE A VALUE BUT HOW CAN I MAKE IT TO BE IN THE FILED OF THE SELECTION SCREEN WHICH EXECUTE THIS SEARCH HELP?

THANKS

Edited by: Matt on Mar 9, 2009 10:16 AM

Re: Search Help using 'F4IF_INT_TABLE_VALUE_REQUEST',

I355602 — Mon, 09 Mar 2009 07:41:04 GMT

Hi,

Refer code:-


REPORT  z_f1f4.

CALL SCREEN 1010.
*&---------------------------------------------------------------------*
*&      Module  GET_F4_HELP  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE get_f4_help INPUT.

  TYPES : BEGIN OF it,
            area TYPE yapn-area,
          END OF it.

  DATA : itab TYPE STANDARD TABLE OF it WITH HEADER LINE,
         tb_dynpfields LIKE dynpread OCCURS 0 WITH HEADER LINE,
         spey TYPE yapn-spey.

  CLEAR:   tb_dynpfields.
  REFRESH: tb_dynpfields.

  MOVE 'YAPN-SPEY' TO tb_dynpfields-fieldname.
  APPEND tb_dynpfields.

  CALL FUNCTION 'DYNP_VALUES_READ'
    EXPORTING
      dyname                               = 'Z_F1F4'
      dynumb                               = '1010'
*   TRANSLATE_TO_UPPER                   = ' '
*   REQUEST                              = ' '
*   PERFORM_CONVERSION_EXITS             = ' '
*   PERFORM_INPUT_CONVERSION             = ' '
*   DETERMINE_LOOP_INDEX                 = ' '
*   START_SEARCH_IN_CURRENT_SCREEN       = ' '
*   START_SEARCH_IN_MAIN_SCREEN          = ' '
*   START_SEARCH_IN_STACKED_SCREEN       = ' '
*   START_SEARCH_ON_SCR_STACKPOS         = ' '
*   SEARCH_OWN_SUBSCREENS_FIRST          = ' '
*   SEARCHPATH_OF_SUBSCREEN_AREAS        = ' '
    TABLES
      dynpfields                           = tb_dynpfields
* EXCEPTIONS
*   INVALID_ABAPWORKAREA                 = 1
*   INVALID_DYNPROFIELD                  = 2
*   INVALID_DYNPRONAME                   = 3
*   INVALID_DYNPRONUMMER                 = 4
*   INVALID_REQUEST                      = 5
*   NO_FIELDDESCRIPTION                  = 6
*   INVALID_PARAMETER                    = 7
*   UNDEFIND_ERROR                       = 8
*   DOUBLE_CONVERSION                    = 9
*   STEPL_NOT_FOUND                      = 10
*   OTHERS                               = 11
            .
  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.

  READ TABLE tb_dynpfields INDEX 1.
  IF sy-subrc EQ 0.
    spey = tb_dynpfields-fieldvalue.
  ELSE.
    spey = ' '.
  ENDIF.

  IF spey EQ ' '.
    itab-area = 'Fresher'.
    APPEND itab.
  ESLE.
    SELECT area FROM yapn
      INTO TABLE itab
    WHERE
      spey = spey.
  ENDIF.

  CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
    EXPORTING
*   DDIC_STRUCTURE         = ' '
      retfield               = 'AREA'
*   PVALKEY                = ' '
     dynpprog               = 'Z_F1F4'
     dynpnr                 = '1010'
     dynprofield            = 'AREA'
*   STEPL                  = 0
*   WINDOW_TITLE           =
*   VALUE                  = ' '
   value_org              = 'S'
*   MULTIPLE_CHOICE        = ' '
*   DISPLAY                = ' '
*   CALLBACK_PROGRAM       = ' '
*   CALLBACK_FORM          = ' '
*   MARK_TAB               =
* IMPORTING
*   USER_RESET             =
    TABLES
      value_tab              = itab
*   FIELD_TAB              =
*   RETURN_TAB             =
*   DYNPFLD_MAPPING        =
  EXCEPTIONS
    PARAMETER_ERROR        = 1
    NO_VALUES_FOUND        = 2
    OTHERS                 = 3
            .
  IF sy-subrc <> 0.
   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
           WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.


ENDMODULE.                 " GET_F4_HELP  INPUT

Hope this helps you.

Regards,

Tarun

Re: Search Help using 'F4IF_INT_TABLE_VALUE_REQUEST',

Former Member — Mon, 09 Mar 2009 07:42:21 GMT

hi,

SELECT-OPTIONS : s_year  FOR tfacd-vjahr NO INTERVALS OBLIGATORY.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR s_year-low.
  PERFORM f4_year CHANGING s_year-low.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR s_year-high.
  PERFORM f4_year CHANGING s_year-high.

FORM f4_year CHANGING p_year TYPE any.

  DATA:
    lt_select_values  LIKE STANDARD TABLE OF ddshretval,
    l_select_values  LIKE  ddshretval.

  CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
    EXPORTING
      retfield        = 'VJAHR'
      dynpprog        = sy-repid
      dynpnr          = sy-dynnr
      window_title    = 'Year'                              "#EC NOTEXT
      value_org       = 'S'
    TABLES
      value_tab       = i_year_tab
      return_tab      = lt_select_values
    EXCEPTIONS
      parameter_error = 1
      no_values_found = 2
      OTHERS          = 3.
  IF sy-subrc EQ 0.
    CLEAR l_select_values.
    READ TABLE lt_select_values INTO l_select_values INDEX 1.
    IF sy-subrc EQ 0.
      p_year = l_select_values-fieldval.
    ENDIF.
  ENDIF.

ENDFORM.                                                    " F4_YEAR

Re: Search Help using 'F4IF_INT_TABLE_VALUE_REQUEST',

former_member242255 — Mon, 09 Mar 2009 07:42:41 GMT

Re: Search Help using 'F4IF_INT_TABLE_VALUE_REQUEST',

Former Member — Mon, 09 Mar 2009 07:44:48 GMT

CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
        EXPORTING
          retfield        = 'SPECID'
          dynpprog        = sy-repid
          value_org       = 'S'
        TABLES
          value_tab       = l_it_dtypdesc
          return_tab      = l_it_ret_tab
        EXCEPTIONS
          parameter_error = 1
          no_values_found = 2
          OTHERS          = 3.
      IF sy-subrc = 0.
        READ TABLE l_it_ret_tab INTO l_wa_ret_tab INDEX 1.
        IF sy-subrc = 0.
          specid = l_wa_ret_tab-fieldval.
        ENDIF.
      ENDIF.

Re: Search Help using 'F4IF_INT_TABLE_VALUE_REQUEST',

Former Member — Mon, 09 Mar 2009 07:53:05 GMT

Hi,

please check this link

http://help.sap.com/saphelp_45b/helpdata/en/9f/dbaac935c111d1829f0000e829fbfe/content.htm

Thanks and regards

Durga.K

Re: Search Help using 'F4IF_INT_TABLE_VALUE_REQUEST',

matt — Mon, 09 Mar 2009 09:17:18 GMT

Do not post in ALL CAPITALS

Re: Search Help using 'F4IF_INT_TABLE_VALUE_REQUEST',

Former Member — Mon, 09 Mar 2009 09:52:33 GMT

hi Ami,

This link can be helpful..

Regards,

Mdi.Deeba