topic User Exit question in Application Development and Automation Discussions

User Exit question

Former Member — Wed, 11 Jan 2006 20:37:28 GMT

Hello,

How can I find the user exit related to a standard transaction?

thanks in advance, best Regards

Gabriel P.

Re: User Exit question

Former Member — Wed, 11 Jan 2006 20:40:13 GMT

You can check for user exit with transaction SMOD.You can search with a description.Then you can create a Project under that enhancement & do the coding for the required exit(component).

Re: User Exit question

govind_seenivasan — Wed, 11 Jan 2006 20:40:15 GMT

Find out the Package/ Devlopement Class of the Standard Tcode then goto SE80, View the package. There you can see the User Exits / Badi's under the Enhancement.

Thanks

Re: User Exit question

Former Member — Thu, 12 Jan 2006 03:28:18 GMT

Hi Gabriel,

I am providing you a program whcih will fetch you the user exits by Transaction code. This report has T/Code as input parameter. Please copy this code to a Zprogram and execute. Then enter the T/code example: "VL03N". Then execute this program this will fetch you the possible user exits.

When you doble click the user EXit the program takes you to "SMOD" transaction.

Hope this will help you.

Lanka

&----

*& Report ZUSREXIT *

*& *

&----

*& *

&----

REPORT z_get_userexit NO STANDARD PAGE HEADING.

&----

*& Enter the transaction code that you want to search through in order

*& to find which Standard SAP User Exits exists.

&----

*& Tables

&----

TABLES : tstc, "SAP Transaction Codes

tadir, "Directory of Repository Objects

modsapt, "SAP Enhancements - Short Texts

modact, "Modifications

trdir, "System table TRDIR

tfdir, "Function Module

enlfdir, "Additional Attributes for Function Modules

tstct. "Transaction Code Texts

&----

*& Variables

&----

DATA : jtab LIKE tadir OCCURS 0 WITH HEADER LINE.

DATA : field1(30).

DATA : v_devclass LIKE tadir-devclass.

&----

*& Selection Screen Parameters

&----

SELECTION-SCREEN BEGIN OF BLOCK a01 WITH FRAME TITLE text-001.

SELECTION-SCREEN SKIP.

PARAMETERS : p_tcode LIKE tstc-tcode OBLIGATORY.

SELECTION-SCREEN SKIP.

SELECTION-SCREEN END OF BLOCK a01.

&----

*& Start of main program

&----

START-OF-SELECTION.

Validate Transaction Code

SELECT SINGLE * FROM tstc

WHERE tcode EQ p_tcode.

Find Repository Objects for transaction code

IF sy-subrc EQ 0.

SELECT SINGLE * FROM tadir

WHERE pgmid = 'R3TR'

AND object = 'PROG'

AND obj_name = tstc-pgmna.

MOVE : tadir-devclass TO v_devclass.

IF sy-subrc NE 0.

SELECT SINGLE * FROM trdir

WHERE name = tstc-pgmna.

IF trdir-subc EQ 'F'.

SELECT SINGLE * FROM tfdir

WHERE pname = tstc-pgmna.

SELECT SINGLE * FROM enlfdir

WHERE funcname = tfdir-funcname.

SELECT SINGLE * FROM tadir

WHERE pgmid = 'R3TR'

AND object = 'FUGR'

AND obj_name = enlfdir-area.

MOVE : tadir-devclass TO v_devclass.

ENDIF.

Find SAP Modifactions

SELECT * FROM tadir

INTO TABLE jtab

WHERE pgmid = 'R3TR'

AND object = 'SMOD'

AND devclass = v_devclass.

SELECT SINGLE * FROM tstct

WHERE sprsl EQ sy-langu

AND tcode EQ p_tcode.

FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.

WRITE:/(19) 'Transaction Code - ',

20(20) p_tcode,

45(50) tstct-ttext.

SKIP.

IF NOT jtab[] IS INITIAL.

WRITE:/(95) sy-uline.

FORMAT COLOR COL_HEADING INTENSIFIED ON.

WRITE:/1 sy-vline,

2 'Exit Name',

21 sy-vline ,

22 'Description',

95 sy-vline.

WRITE:/(95) sy-uline.

LOOP AT jtab.

SELECT SINGLE * FROM modsapt

WHERE sprsl = sy-langu AND

name = jtab-obj_name.

FORMAT COLOR COL_NORMAL INTENSIFIED OFF.

WRITE:/1 sy-vline,

2 jtab-obj_name HOTSPOT ON,

21 sy-vline ,

22 modsapt-modtext,

95 sy-vline.

ENDLOOP.

WRITE:/(95) sy-uline.

DESCRIBE TABLE jtab.

SKIP.

FORMAT COLOR COL_TOTAL INTENSIFIED ON.

WRITE:/ 'No of Exits:' , sy-tfill.

ELSE.

FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.

WRITE:/(95) 'No User Exit exists'.

ENDIF.

ELSE.

FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.

WRITE:/(95) 'Transaction Code Does Not Exist'.

ENDIF.

Take the user to SMOD for the Exit that was selected.

AT LINE-SELECTION.

GET CURSOR FIELD field1.

CHECK field1(4) EQ 'JTAB'.

SET PARAMETER ID 'MON' FIELD sy-lisel+1(10).

CALL TRANSACTION 'SMOD' AND SKIP FIRST SCREEN.

Message was edited by: Lanka Murthy

Re: User Exit question

Former Member — Thu, 12 Jan 2006 03:59:03 GMT

use the following code enter Txn Code it will give ur list of all Exits Double click on it it will take u to SMOD Txn.

*&---------------------------------------------------------------------*
*& Report  Z_REPORT_FIND_USER_EXITS                                    *
*&
*&---------------------------------------------------------------------*

REPORT z_report_find_user_exits NO STANDARD PAGE HEADING.

*&---------------------------------------------------------------------*
*&  Enter the transaction code that you want to search through in order
*&  to find which Standard SAP User Exits exists.
*&---------------------------------------------------------------------*
*&---------------------------------------------------------------------*
*& Tables
*&---------------------------------------------------------------------*

TABLES : tstc,     "SAP Transaction Codes
         tadir,    "Directory of Repository Objects
         modsapt,  "SAP Enhancements - Short Texts
         modact,   "Modifications
         trdir,    "System table TRDIR
         tfdir,    "Function Module
         enlfdir,  "Additional Attributes for Function Modules
         tstct.    "Transaction Code Texts
*&---------------------------------------------------------------------*
*& Variables
*&---------------------------------------------------------------------*
DATA : jtab LIKE tadir OCCURS 0 WITH HEADER LINE.
DATA : field1(30).
DATA : v_devclass LIKE tadir-devclass.
*&---------------------------------------------------------------------*
*& Selection Screen Parameters
*&---------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK a01 WITH FRAME TITLE text-001.
SELECTION-SCREEN SKIP.
PARAMETERS : p_tcode LIKE tstc-tcode OBLIGATORY.
SELECTION-SCREEN SKIP.
SELECTION-SCREEN END OF BLOCK a01.

START-OF-SELECTION.
* Validate Transaction Code
  SELECT SINGLE * FROM tstc WHERE tcode EQ p_tcode.

* Find Repository Objects for transaction code
  IF sy-subrc EQ 0.
    SELECT SINGLE * FROM tadir
       WHERE pgmid    = 'R3TR' AND
             object   = 'PROG' AND
             obj_name = tstc-pgmna.

    MOVE : tadir-devclass TO v_devclass.

    IF sy-subrc NE 0.
      SELECT SINGLE * FROM trdir WHERE name = tstc-pgmna.

      IF trdir-subc EQ 'F'.
        SELECT SINGLE * FROM tfdir WHERE pname = tstc-pgmna.

        SELECT SINGLE * FROM enlfdir WHERE funcname = tfdir-funcname.

        SELECT SINGLE * FROM tadir
                        WHERE pgmid    = 'R3TR' AND
                              object   = 'FUGR' AND
                              obj_name = enlfdir-area.

        MOVE : tadir-devclass TO v_devclass.
      ENDIF.
    ENDIF.

* Find SAP Modifactions
    SELECT * FROM tadir INTO TABLE jtab
              WHERE pgmid    = 'R3TR' AND
                    object   = 'SMOD' AND
                    devclass = v_devclass.

    SELECT SINGLE * FROM tstct
              WHERE sprsl EQ sy-langu AND
                    tcode EQ p_tcode.

    FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.
    WRITE:/(19) 'Transaction Code - ',
            20(20) p_tcode,
            45(50) tstct-ttext.
    SKIP.

    IF NOT jtab[] IS INITIAL.
      WRITE:/(95) sy-uline.

      FORMAT COLOR COL_HEADING INTENSIFIED ON.
      WRITE:/1 sy-vline,
            2  'Exit Name',   21 sy-vline ,
            22 'Description', 95 sy-vline.
      WRITE:/(95) sy-uline.

      LOOP AT jtab.
        SELECT SINGLE * FROM modsapt
                    WHERE sprsl = sy-langu AND
                          name = jtab-obj_name.

        FORMAT COLOR COL_NORMAL INTENSIFIED OFF.

        WRITE:/1  sy-vline,
               2  jtab-obj_name HOTSPOT ON, 21 sy-vline ,
               22 modsapt-modtext,          95 sy-vline.
      ENDLOOP.

      WRITE:/(95) sy-uline.
      DESCRIBE TABLE jtab.
      SKIP.

      FORMAT COLOR COL_TOTAL INTENSIFIED ON.
      WRITE:/ 'No of Exits:' , sy-tfill.
    ELSE.
      FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
      WRITE:/(95) 'No User Exit exists'.
    ENDIF.
  ELSE.
    FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
    WRITE:/(95) 'Transaction Code Does Not Exist'.
  ENDIF.

* Take the user to SMOD for the Exit that was selected.
AT LINE-SELECTION.
  GET CURSOR FIELD field1.
  CHECK field1(4) EQ 'JTAB'.
  SET PARAMETER ID 'MON' FIELD sy-lisel+1(10).
  CALL TRANSACTION 'SMOD' AND SKIP FIRST SCREEN.

regards

abhishek suppal